blob: 37a24265c7cca78e7ee17b1380d59e63f894f7c7 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
|
# Maintainer: Thomas Jost <schnouki@schnouki.net>
# Contributor: Juergen Hoetzel <juergen@archlinux.org>
# Contributor: Renchi Raju <renchi@green.tam.uiuc.edu>
pkgname=emacs-pretest
_pkgname=emacs
pkgver=24.0.91
pkgrel=1
pkgdesc="The extensible, customizable, self-documenting real-time display editor -- pretest version"
arch=('i686' 'x86_64')
url="http://www.gnu.org/software/emacs/emacs.html"
license=('GPL3')
depends=('librsvg' 'gpm' 'giflib' 'libxpm' 'gtk2' 'hicolor-icon-theme' 'gconf' 'desktop-file-utils' 'alsa-lib')
provides=("emacs=$pkgver")
conflicts=("emacs" "emacs-nox" "emacs-bzr" "emacs-git" "emacs-cvs")
install=emacs.install
source=(ftp://alpha.gnu.org/gnu/emacs/pretest/$_pkgname-$pkgver.tar.gz emacs.desktop)
md5sums=('6f517a5c2cf39b6f59940c6910f37b06'
'8af038d2ba4561271e935bb444ceb4e3')
sha256sums=('1850909dccde9a331b4585bdc3d26a30b90a81a7d2469536fddd6ba61d246bbe'
'dba3652cdfd4193d264cf9ebafcef3e6be4af3f83bdf187d421f8e4c07f94b39')
build() {
cd "$srcdir"/$_pkgname-$pkgver
./configure --prefix=/usr --sysconfdir=/etc --libexecdir=/usr/lib \
--localstatedir=/var --with-x-toolkit=gtk --with-xft
make
}
package() {
cd "$srcdir"/$_pkgname-$pkgver
make DESTDIR="$pkgdir" install
# remove conflict with ctags package
mv "$pkgdir"/usr/bin/{ctags,ctags.emacs}
mv "$pkgdir"/usr/share/man/man1/{ctags.1,ctags.emacs.1}.gz
# fix all the 777 perms on directories
find "$pkgdir"/usr/share/emacs/$pkgver -type d -exec chmod 755 {} \;
# fix user/root permissions on usr/share files
find "$pkgdir"/usr/share/emacs/$pkgver -exec chown root:root {} \;
# fix perms on /var/games
chmod 775 "$pkgdir"/var/games
chmod 775 "$pkgdir"/var/games/emacs
chmod 664 "$pkgdir"/var/games/emacs/*
chown -R root:games "$pkgdir"/var/games
# fix FS#9253
mkdir -p "$pkgdir"/usr/share/pixmaps "$pkgdir"/usr/share/applications
install -D -m644 "$srcdir"/$_pkgname.desktop "$pkgdir"/usr/share/applications
ln -s ../emacs/$pkgver/etc/images/icons/hicolor/48x48/apps/emacs.png "$pkgdir"/usr/share/pixmaps/emacs-icon.png
}
|