summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 6797c2e4e38588ffc503d4465d0ba2127a3c2e6c (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
# $Id$
# Maintainer: Lukas Jirkovsky <l.jirkovsky@gmail.com>
# Maintainer: Bruno Pagani <archange@archlinux.org>

_pkgname=embree
pkgver=2.17.7
pkgname=${_pkgname}2
pkgrel=1
pkgdesc="A collection of high-performance ray tracing kernels. Version 2"
arch=('x86_64')
url="https://embree.github.io/"
license=('Apache')
depends=('intel-tbb')
makedepends=('cmake' 'ispc' 'freeglut' 'libxmu' 'openexr')
provides=("embree-isa=${pkgver}" "$_pkgname=${pkgver}" )
replaces=("embree-isa=${pkgver}" "$_pkgname<=${pkgver}" )
source=("${_pkgname}-${pkgver}.tar.gz::https://github.com/embree/embree/archive/v${pkgver}.tar.gz")
sha256sums=('c0694f287fa1fbb382aba3a895702e248d92f7e89c0e5f64aefee965482ec04c')

build() {
    cd ${_pkgname}-${pkgver}
    cmake . \
      -DCMAKE_INSTALL_PREFIX=/usr \
      -DCMAKE_INSTALL_LIBDIR=lib \
      -DCMAKE_BUILD_TYPE=Release \
      -DEMBREE_TUTORIALS=OFF \
      -DEMBREE_MAX_ISA="AVX512SKX"
    # Embree detects actual ISA at runtime
    make
}

package() {
    cd ${_pkgname}-${pkgver}
    make DESTDIR="${pkgdir}" install
    #prevent collision with official embree package
    rm ${pkgdir}/usr/lib/libembree.so
}