blob: 344f68d10e5d224b3b659004681822a6b001a098 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
|
# Maintainer: Nicola Hinssen <nicola.hinssen@gmail.com>
# Contributor: Bjorn Nostvold <bjorn.nostvold@gmail.com>
# Contributor: Maxime Gauduin <alucryd@archlinux.org>
# Contributor: Daniel Seymour <dannyseeless@gmail.com>
pkgname=emby-server-beta
pkgver=4.7.0.12
pkgrel=1
_ffmpeg_ver=2020_05_23
_ffdetect_ver=2020_05_23
pkgdesc='Bring together your videos, music, photos, and live television'
arch=('x86_64')
url='https://emby.media'
license=('custom')
depends=('alsa-lib'
'aom'
'bzip2'
'dotnet-runtime-3.1'
'dotnet-host-bin'
'expat'
'fontconfig'
'fribidi'
'glibc'
'gmp'
'gnutls'
'lame'
'libass.so'
'libdav1d.so'
'libdrm'
'libfreetype.so'
'libjpeg-turbo'
'libmfx'
'libpng'
'libtheora'
'libva-drm.so'
'libva.so'
'libvorbisenc.so'
'libvorbis.so'
'libwebp'
'libx264.so'
'opus'
'skia-sharp'
'sqlite'
'zlib'
'zvbi')
makedepends=('ffnvcodec-headers8.1'
'nasm')
optdepends=('intel-media-sdk: Intel QuickSync support (requires Emby Premiere)'
'nvidia-utils: Nvidia NVDEC/NVENC support (requires Emby Premiere)')
provides=('emby-server')
conflicts=('emby-server')
source=("https://github.com/MediaBrowser/Emby.Releases/releases/download/${pkgver}/embyserver-netcore_${pkgver}.zip"
"https://mediabrowser.github.io/embytools/ffmpeg-${_ffmpeg_ver}.tar.gz"
"https://mediabrowser.github.io/embytools/ffdetect-${_ffdetect_ver}-x64.tar.xz"
'emby-server'
'emby-server.conf'
'emby-server.service'
'license.docx')
noextract=(license.docx)
backup=('etc/conf.d/emby-server')
install=emby-server.install
sha256sums=('30b84478f5512bb480f03473ac14aa3143715bdc79b1f0311c47af2fa60f635e'
'ed2fde500b705b06a0b82a9bf6b367c63b0fc899f69f77691bc68d61f3862a77'
'c66e73c86ebfdfb169dbdc3c6731f09bd82382dda3fb8a77abe19d6973c09b51'
'0351d6e9118853e3aa275d62b67dce4444b3d85130b05fb889b2069f364f47ca'
'5e3470f834808babe7d60b8d86f462e7945c3617499539e5af45eb55d7b87b23'
'a7f2e38d2d196984d1c1632c851215aea9072b3af998d10a6b68477ad886ea14'
'a6d7ea65dcb06392479a85e1a10a7aeb872d803da6f784f6935fcd4ee63008c6')
prepare() {
rm -rf system/{electron,runtimes/{osx,tizen*,win*}}
}
build() {
cd ffmpeg-${_ffmpeg_ver}_*
export PKG_CONFIG_PATH=/usr/lib/ffnvcodec8.1/pkgconfig
./configure \
--disable-doc \
--disable-ffplay \
--disable-shared \
--disable-vdpau \
--disable-libxcb \
--disable-lzma \
--disable-sdl2 \
--disable-xlib \
--enable-fontconfig \
--enable-gmp \
--enable-gnutls \
--enable-gpl \
--enable-libaom \
--enable-libass \
--enable-libdav1d \
--enable-libdrm \
--enable-libfreetype \
--enable-libfribidi \
--enable-libmfx \
--enable-libmp3lame \
--enable-libopus \
--enable-libtheora \
--enable-libvorbis \
--enable-libwebp \
--enable-libx264 \
--enable-libzvbi \
--enable-version3 \
--enable-nvdec \
--enable-nvenc \
--enable-static \
--enable-vaapi
make
}
package() {
install -dm 755 "${pkgdir}"/usr/lib
cp -dr --no-preserve='ownership' system "${pkgdir}"/usr/lib/emby-server
ln -s ../libSkiaSharp.so.68.0.0 "${pkgdir}"/usr/lib/emby-server/libSkiaSharp.so
install -Dm 755 emby-server -t "${pkgdir}"/usr/bin/
install -Dm 755 bin/ffdetect "${pkgdir}"/usr/bin/ffdetect-emby
install -Dm 755 ffmpeg-${_ffmpeg_ver}_*/ffmpeg "${pkgdir}"/usr/bin/ffmpeg-emby
install -Dm 755 ffmpeg-${_ffmpeg_ver}_*/ffprobe "${pkgdir}"/usr/bin/ffprobe-emby
install -Dm 644 emby-server.service -t "${pkgdir}"/usr/lib/systemd/system/
install -Dm 644 emby-server.conf "${pkgdir}"/etc/conf.d/emby-server
install -Dm 644 license.docx -t "${pkgdir}"/usr/share/licenses/$pkgname/license.docx
}
|