blob: cca0dd9d3a19496f9e4aa97260cb41727bc1ce30 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
|
# Contributor: Andrew Rabert <draje@nullsum.net>
pkgname=emby-server-unlocked
pkgver=3.2.26.0
pkgrel=3
pkgdesc='Emby Server compiled with a patch to unlock Emby Premiere features'
arch=('i686' 'x86_64')
url='http://emby.media'
license=('GPL2')
depends=('ffmpeg' 'imagemagick' 'mono' 'referenceassemblies-pcl' 'sqlite')
install='emby-server.install'
provides=('emby-server')
source=("emby-server-${pkgver}.tar.gz::https://github.com/MediaBrowser/Emby/archive/${pkgver}.tar.gz"
'emby-server'
'emby-migrate-database'
'emby-server.conf'
'emby-server.service'
'PluginSecurityManager.cs.patch')
backup=('etc/conf.d/emby-server')
sha256sums=('8d1ee6e5da6589dbdda52df13ffe9ef0a9a5025159e0efcb36334214f3c7246c'
'7b1974f7bba8ac4b76e51ef7fe1257d165c7c4abbd0915e192391336048a3d74'
'b25bf83a0ab371aff3b13b82f7af71b51bfe6d7e51eb8a8a3dd8f0774ffce6a5'
'c9ad78f3e2f0ffcb4ee66bb3e99249fcd283dc9fee17895b9265dc733288b953'
'8a91ea49a1699c820c4a180710072cba1d6d5c10e45df97477ff6a898f4e1d70'
'c501e359a7c1268374e8b1cb8be6afe324d8a16788ba27c980efc7bf286ce9d5')
prepare() {
cd Emby-${pkgver}
sed 's/libMagickWand-6.Q8.so/libMagickWand-6.Q16HDRI.so/' -i MediaBrowser.Server.Mono/ImageMagickSharp.dll.config
}
build() {
cd Emby-${pkgver}
patch -N -p1 -r - Emby.Server.Implementations/Security/PluginSecurityManager.cs < ../PluginSecurityManager.cs.patch
xbuild \
/p:Configuration='Release Mono' \
/p:Platform='Any CPU' \
/p:OutputPath="${srcdir}/build" \
/t:build MediaBrowser.sln
mono --aot='full' -O='all' ../build/MediaBrowser.Server.Mono.exe
}
package() {
install -dm 755 "${pkgdir}"/{etc/conf.d,usr/{bin,lib/systemd/system}}
cp -dr --no-preserve='ownership' build "${pkgdir}"/usr/lib/emby-server
find "${pkgdir}" -type f -name *.dylib -delete
install -m 755 emby-server "${pkgdir}"/usr/bin/
install -m 755 emby-migrate-database "${pkgdir}"/usr/bin/
install -m 644 emby-server.service "${pkgdir}"/usr/lib/systemd/system/
install -m 644 emby-server.conf "${pkgdir}"/etc/conf.d/emby-server
install -dm 755 "${pkgdir}"/var/lib/emby
chown 422:422 -R "${pkgdir}"/var/lib/emby
}
|