blob: e4299fb1ac09762a162dbf89f8cf7e2bc26f4673 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
|
# Maintainer: orhun <orhunparmaksiz@gmail.com>
# https://github.com/orhun/pkgbuilds
pkgname=emptty
pkgdesc="Dead simple CLI Display Manager on TTY"
pkgver=0.6.2
pkgrel=1
arch=('x86_64')
url="https://github.com/tvrzna/emptty"
license=('MIT')
depends=('pam' 'libx11')
makedepends=('go' 'git')
optdepends=('xorg-server: default display server'
'xorg-xauth: required if using xorg-server'
'util-linux: mcookie required if using xorg-server'
'wayland: alternative to xorg-server')
backup=('etc/emptty/conf')
install="$pkgname.install"
source=("$pkgname-$pkgver.tar.gz::$url/archive/v$pkgver.tar.gz")
sha512sums=('489003c567bcbe1c704a349aff516c4179a9a8ca5a3dc70b1a86772d8bf60baffd3fe85dd5423ade29b48cd0240bd47f4fec244c3a1b6aeaacef5d6f4f67aa5e')
build() {
cd "$pkgname-$pkgver"
export CGO_CPPFLAGS="${CPPFLAGS}"
export CGO_CFLAGS="${CFLAGS}"
export CGO_CXXFLAGS="${CXXFLAGS}"
export CGO_LDFLAGS="${LDFLAGS}"
export GOFLAGS="-buildmode=pie -trimpath -ldflags=-linkmode=external -mod=readonly -modcacherw"
make build
}
package() {
cd "$pkgname-$pkgver"
make DESTDIR="$pkgdir/" install-all
make DESTDIR="$pkgdir/" install-config
make DESTDIR="$pkgdir/" install-systemd
install -Dm 644 README.md -t "$pkgdir/usr/share/doc/$pkgname"
install -Dm 644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname"
}
|