PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50

# Maintainer: xiretza <aur@xiretza.xyz>
_pkgname=engage
pkgname=$_pkgname-git
pkgver=0.2.0.r14.gdd6f4d9
pkgrel=1
pkgdesc="A task runner with DAG-based parallelism"
arch=(x86_64)
url="https://or.computer.surgery/charles/engage"
license=('Apache-2.0 OR MIT')
depends=('glibc' 'gcc-libs')
makedepends=('git' 'rust' 'cargo')
provides=("$_pkgname=$pkgver")
conflicts=("$_pkgname")
source=("$_pkgname::git+$url.git")
sha256sums=('SKIP')

pkgver() {
	cd "$_pkgname"

	git describe --long --tags --abbrev=7 | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

prepare() {
	cd "$_pkgname"

	export RUSTUP_TOOLCHAIN=stable
	cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
}

build() {
	cd "$_pkgname"

	export RUSTUP_TOOLCHAIN=stable
	export CARGO_TARGET_DIR=target
	cargo build --frozen --release --all-features
}

check() {
	cd "$_pkgname"

	export RUSTUP_TOOLCHAIN=stable
	cargo test --frozen --all-features
}

package() {
	cd "$_pkgname"

	install -Dm755 -t "$pkgdir/usr/bin/" "target/release/$_pkgname"
	install -Dm644 -t "$pkgdir/usr/share/licenses/$pkgname/" LICENSE-MIT.md LICENSE-Apache-2.0.md
}