blob: 1c632af554377af701b1ff585aec200d6791cd86 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
|
# Maintainer: Carsten Haitzler <raster@rasterman.com>
# Contributor: Gavin Fernandes <gavinfernandes2012@gmail.com>
# Contributor: Doug Newgard <scimmia22 at outlook dot com>
# Contributor: Ronald van Haren <ronald.archlinux.org>
_pkgname=enlightenment
pkgname=$_pkgname-git
pkgver=0.22.99.23236.g9581a4828
pkgrel=1
pkgdesc="Enlightenment window manager - Development version"
arch=('i686' 'x86_64')
url="http://www.enlightenment.org"
license=('BSD')
depends=('efl-git' 'xcb-util-keysyms' 'udisks2' 'wayland'
'xorg-server-xwayland')
[[ ! $(pacman -T bluez-libs) ]] && depends+=('bluez-libs') #l2ping support in enlightenment_sys is detected at build time
makedepends=('git' 'meson')
optdepends=('acpid: power events on laptop lid close'
'bc: calculator in everything module'
'bluez4: bluetooth module'
'connman: network module'
'gdb: create backtraces on crash'
'geoclue2: geolocation module'
'packagekit: packagekit module')
provides=("$_pkgname=$pkgver" 'notification-daemon')
conflicts=("$_pkgname")
backup=('etc/enlightenment/sysactions.conf'
'etc/xdg/menus/e-applications.menu')
options=('debug')
source=("git+https://git.enlightenment.org/core/$_pkgname.git")
sha256sums=('SKIP')
pkgver() {
cd $_pkgname
local v_ver=$(grep version meson.build | head -1 | sed s/version//g | tr ":'," " " | awk '{print $1}')
printf "%s.%s.g%s" "$v_ver" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
build() {
cd $_pkgname
export CFLAGS="$CFLAGS -fvisibility=hidden"
rm -rf build
meson --prefix=/usr \
-Dwayland=true \
. build
ninja -C build
}
package() {
cd $_pkgname
DESTDIR="$pkgdir" ninja -C build install
install -Dm644 -t "$pkgdir/usr/share/doc/$_pkgname/" README
install -Dm644 -t "$pkgdir/usr/share/licenses/$pkgname/" AUTHORS COPYING
}
|