PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33

pkgname=eolie-next-git
_gitname=eolie
pkgver=0.9.101.r1.g7415fa18
pkgrel=1
pkgdesc="Simple web browser for GNOME (dev branch)"
arch=('x86_64' 'i686')
url="https://wiki.gnome.org/Apps/Eolie"
license=('GPL3')
depends=('gtkspell3' 'python-cairo' 'python-dateutil' 'python-gobject' 'webkit2gtk')
makedepends=('git' 'gobject-introspection' 'meson')
optdepends=('python-beautifulsoup4: Import html bookmarks'
            'python-crypto: Firefox Sync support' 
            'python-fxa: Firefox Sync support'
            'python-pyopenssl: Show SSL certificates'
            'python-requests-hawk: Firefox Sync support')
source=("git+https://gitlab.gnome.org/World/eolie.git")
sha256sums=('SKIP')
conflicts=('eolie' 'eolie-git' 'eolie-stable-git')
provides=("eolie=$pkgver")

pkgver() {
	cd "${_gitname}"
	git describe --tags | sed 's/-/+/g'
}

build() {
	arch-meson "${_gitname}" build
	ninja -C build
}

package() {
	DESTDIR="$pkgdir" meson install -C build
}