blob: a1c3612dd0bd4bf2c92afc7cf4d905e35e49c769 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
|
# Maintainer: Que Quotion <quequotion@bugmenot.com>
# Contributor: Adria Arrufat <adria DOT arrufat+aur AT protonmail DOT ch>
pkgname=epiphany-pantheon
pkgver=3.28.0.1+1ubuntu1+r21.dbc305d50
pkgrel=1
pkgdesc="A GNOME web browser based on the WebKit rendering engine, with elementary OS patches"
url="https://gitlab.gnome.org/GNOME/epiphany/"
arch=('i686' 'x86_64')
license=('GPL')
depends=('webkit2gtk>=2.19.4' gcr libhttpseverywhere libdazzle gst-libav)
makedepends=(meson docbook-xml startup-notification lsb-release
gobject-introspection yelp-tools autoconf-archive appstream-glib)
groups=(pantheon-unstable pantheon-qq)
replaces=(epiphany-pantheon-bzr)
provides=(epiphany epiphany-sync)
conflicts=(epiphany)
source=("git+https://github.com/elementary/os-patches.git#branch=epiphany-browser-bionic-patched"
epiphany-sync{,.service})
sha256sums=('SKIP'
'cf90f3ea93fff8c61f82da40c8d07d5db2f33dc9a0d91408a6ffc4142bbedd20'
'ce1ac321d7bf9d88638634a141dfcb99119fc59ee44c4892e0874608e85006ba')
pkgver() {
cd "os-patches"
printf "3.28.0.1+1ubuntu1+r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
build() {
cd "os-patches"
[ -d build ] && rm -rf build
arch-meson build -Denable_https_everywhere=true
ninja -C build
}
package() {
cd "os-patches"
DESTDIR="${pkgdir}" ninja -C build install
install -Dm 755 {"${srcdir}","${pkgdir}"/usr/bin}/epiphany-sync
install -Dm 644 {"${srcdir}","${pkgdir}"/usr/lib/systemd/user}/epiphany-sync.service
}
|