blob: 64c22c7a6b3fe2f77d56646e3bed083de2e15632 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
|
pkgname=epson-inkjet-printer-escpr2
pkgver=1.0.15
pkgrel=1
pkgdesc="Epson Inkjet Printer Driver 2 (ESC/P-R) for Linux"
arch=('i686' 'x86_64' 'armv6h' 'armv7h')
url="http://download.ebz.epson.net/dsc/search/01/search/?OSC=LX"
license=('GPL2')
depends=('cups' 'ghostscript')
optdepends=('imagescan: scanner support')
options=('!libtool')
source=('https://download3.ebz.epson.net/dsc/f/03/00/07/27/77/89ad82d02fc769f9c8e996dedbe64b2337b99ea2/epson-inkjet-printer-escpr2-1.0.15-1lsb3.2.src.rpm'
'bug_x86_64.patch')
sha256sums=('63b968c17c582f509b62869e1b8c85a85973a6e051834dab1105fced8b1372e7'
'44160b2ef140e97137d65c4db7a50cfe40399ab8691caaeaf43c08f758b8c545')
prepare() {
tar xvf "$pkgname-$pkgver-$pkgrel"lsb3.2.tar.gz
cd "$pkgname-$pkgver"
patch -p1 -i "${srcdir}/bug_x86_64.patch"
}
build() {
cd "$pkgname-$pkgver"
./configure --prefix=/usr \
--with-cupsfilterdir=/usr/lib/cups/filter \
--with-cupsppddir=/usr/share/ppd
make
}
package() {
cd "$pkgname-$pkgver"
make DESTDIR="$pkgdir" install
}
|