blob: a183c38aae04e2ded792c4889f6756d459983cff (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
|
# Maintainer: Doug Newgard <scimmia22 at outlook dot com>
_pkgname=eruler
pkgname=$_pkgname-git
pkgver=0.1.0.r9.386f9e7
pkgrel=1
pkgdesc="On-Screen Ruler and Measurement Tools using EFL"
arch=('i686' 'x86_64')
url="http://www.enlightenment.org"
license=('GPL')
depends=('elementary')
makedepends=('git')
provides=("$_pkgname=$pkgver")
conflicts=("$_pkgname")
source=("git://git.enlightenment.org/apps/$_pkgname.git")
sha256sums=('SKIP')
pkgver() {
cd "$srcdir/$_pkgname"
local v_ver=$(awk -F , '/^AC_INIT/ {gsub(/[\[\] -]/, ""); print $2}' configure.ac)
printf "$v_ver.r$(git rev-list --count HEAD).$(git rev-parse --short HEAD)"
}
build() {
cd "$srcdir/$_pkgname"
export CFLAGS="$CFLAGS -fvisibility=hidden"
./autogen.sh --prefix=/usr
make
}
package() {
cd "$srcdir/$_pkgname"
make DESTDIR="$pkgdir" install
# install text files
install -d "$pkgdir/usr/share/doc/$_pkgname/"
install -m644 -t "$pkgdir/usr/share/doc/$_pkgname/" AUTHORS README
}
|