blob: 7372c4ea7325b0b1b087b02cc4a18b5d48a4bdd2 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
|
# Maintainer: Daniel Milde <daniel@milde.cz>
# Contributor: George Rawlinson <george@rawlinson.net.nz>
pkgname=esbuild
pkgver=0.16.4
pkgrel=1
pkgdesc="An extremely fast JavaScript and CSS bundler and minifier."
arch=('x86_64' 'i686' 'aarch64' 'armv7h')
url="https://esbuild.github.io/"
license=('MIT')
makedepends=('go')
source=("$pkgname-$pkgver.tar.gz::https://github.com/evanw/esbuild/archive/v$pkgver.tar.gz")
b2sums=('ffa5e842c608f79ea3d98d5ec6c330362a9b63b998992e707ce39cd56d4a0e440b5c1c27d9597baacad1a56b173ff111af23243ddb19afbd5445e7291dab754a')
prepare() {
cd "$pkgname-$pkgver"
mkdir -p build
}
build () {
cd "$pkgname-$pkgver"
export CGO_CPPFLAGS="${CPPFLAGS}"
export CGO_CFLAGS="${CFLAGS}"
export CGO_CXXFLAGS="${CXXFLAGS}"
export CGO_LDFLAGS="${LDFLAGS}"
export GOFLAGS="-buildmode=pie -trimpath -ldflags=-linkmode=external -mod=readonly -modcacherw"
go build -o build ./cmd/...
}
package() {
cd "$pkgname-$pkgver"
install -Dm755 -t "$pkgdir/usr/bin" "build/$pkgname"
install -Dm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE.md
}
|