blob: 6ec296b49208ed265f1c4b9c505d256e962ffe88 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
|
# Maintainer: Daniel Milde <daniel@milde.cz>
# Contributor: George Rawlinson <george@rawlinson.net.nz>
_name=esbuild
pkgname=${_name}
pkgver=0.16.11
pkgrel=1
pkgdesc="An extremely fast JavaScript and CSS bundler and minifier."
arch=('x86_64' 'i686' 'aarch64' 'armv7h')
url="https://${_name}.github.io/"
license=('MIT')
makedepends=('go')
_snapshot="${_name}-${pkgver}"
source=("${_snapshot}.tar.gz::https://github.com/evanw/${_name}/archive/v${pkgver}.tar.gz")
b2sums=('f13ad33d3b7a96595795fc2300b67b5851dcca3b3a399be668f06e94b082f2bae1acef55f528208a343a565ea12c47d2445b5b893b9d98b9d2efcba9614009fc')
build() {
set -a
CGO_CPPFLAGS="${CPPFLAGS}"
CGO_CFLAGS="${CFLAGS}"
CGO_CXXFLAGS="${CXXFLAGS}"
CGO_LDFLAGS="${LDFLAGS}"
GOFLAGS="-buildmode=pie -trimpath -ldflags=-linkmode=external -mod=readonly -modcacherw"
set +a
cd "${_snapshot}"
go build -o "${srcdir}/build/" "./cmd/..."
}
package() {
local bin="/usr/bin/${_name}"
install -Dm755 "build/${_name}" "${pkgdir}${bin}"
local profile="/etc/profile.d"
install -dm755 "${pkgdir}${profile}"
echo "export ESBUILD_BINARY_PATH='${bin}'" > "${pkgdir}${profile}/${_name}.sh"
cd "${_snapshot}"
install -Dm644 -t "${pkgdir}/usr/share/licenses/${pkgname}" "LICENSE.md"
}
|