blob: 9f16d99ec9f5221bba05819cac50adbfdcac7f06 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
|
# Maintainer: Daniel Milde <daniel@milde.cz>
# Contributor: George Rawlinson <george@rawlinson.net.nz>
pkgname=esbuild
pkgver=0.14.38
pkgrel=1
pkgdesc="An extremely fast JavaScript/TypeScript bundler and minifier"
arch=('x86_64')
url="https://github.com/evanw/esbuild"
license=('MIT')
depends=('glibc')
makedepends=('go')
source=("$pkgname-$pkgver.tar.gz::$url/archive/v$pkgver.tar.gz")
b2sums=('a76c8a943dc63704176afa923c99da55fa9c3917b7a3c95a71ff505cbf5f43e86d2e959027da7ef122fba81bd64d18738a04ef47d3a3ce2f8f226681edd606c2')
prepare() {
cd "$pkgname-$pkgver"
mkdir -p build
}
build () {
cd "$pkgname-$pkgver"
export CGO_CPPFLAGS="${CPPFLAGS}"
export CGO_CFLAGS="${CFLAGS}"
export CGO_CXXFLAGS="${CXXFLAGS}"
export CGO_LDFLAGS="${LDFLAGS}"
export GOFLAGS="-buildmode=pie -trimpath -ldflags=-linkmode=external -mod=readonly -modcacherw"
go build -o build ./cmd/...
}
package() {
cd "$pkgname-$pkgver"
install -Dm755 -t "$pkgdir/usr/bin" "build/$pkgname"
install -Dm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE.md
}
|