blob: 439ac9f9e36a94b960899126662120df3e6bef9b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
|
# Maintainer: Daniel Milde <daniel@milde.cz>
# Contributor: George Rawlinson <george@rawlinson.net.nz>
_name=esbuild
pkgname=${_name}
pkgver=0.16.13
pkgrel=1
pkgdesc="An extremely fast JavaScript and CSS bundler and minifier."
arch=('x86_64' 'i686' 'aarch64' 'armv7h')
url="https://${_name}.github.io/"
license=('MIT')
makedepends=('go')
_snapshot="${_name}-${pkgver}"
source=("${_snapshot}.tar.gz::https://github.com/evanw/${_name}/archive/v${pkgver}.tar.gz")
b2sums=('4122dd0198171bf607401a8255620b4d0bb04281b42685aa78d8a55ba251455f614f603e8745f00abe4e0dba621c3c6c2b0555adf05f233a9a8ac35a90133acc')
build() {
set -a
CGO_CPPFLAGS="${CPPFLAGS}"
CGO_CFLAGS="${CFLAGS}"
CGO_CXXFLAGS="${CXXFLAGS}"
CGO_LDFLAGS="${LDFLAGS}"
GOFLAGS="-buildmode=pie -trimpath -ldflags=-linkmode=external -mod=readonly -modcacherw"
set +a
cd "${_snapshot}"
go build -o "${srcdir}/build/" "./cmd/..."
}
package() {
local bin="/usr/bin/${_name}"
install -Dm755 "build/${_name}" "${pkgdir}${bin}"
local profile="/etc/profile.d"
install -dm755 "${pkgdir}${profile}"
echo "export ESBUILD_BINARY_PATH='${bin}'" > "${pkgdir}${profile}/${_name}.sh"
cd "${_snapshot}"
install -Dm644 -t "${pkgdir}/usr/share/licenses/${pkgname}" "LICENSE.md"
}
|