blob: cdf8eb5703a6b3e3a8c57ac260dc65b16e334173 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
|
# Maintainer: marmis <tiagodepalves@gmail.com>
# Contributor: "marmis" Tiago de Paula <tiagodepalves@gmail.com>
# Contributor: "ilpianista" Andrea Scarpino <andrea@archlinux.org>
# Contributor: "bidulock" Brian Bidulock <bidulock@openss7.org>
# Contributor: SpepS <dreamspepser@yahoo.it>
# Contributor: Jan de Groot <jgc@archlinux.org>
pkgname=esound
pkgdesc='Enlightened Sound Daemon'
pkgver=0.2.41
pkgrel=6
url='https://gitlab.gnome.org/Archive/esound'
arch=('i686' 'x86_64')
license=('GPL-2.0-or-later AND LGPL-2.0-or-later')
makedepends=('autoconf' 'automake' 'libtool')
depends=('audiofile' 'alsa-lib' 'glibc' 'sh')
optdepends=('pipewire-alsa: User service for the PipeWire stack.')
provides=("esd=${pkgver}")
conflicts=('esd')
options=(!libtool)
backup=('etc/esd.conf')
source=("http://ftp.gnome.org/pub/GNOME/sources/${pkgname}/${pkgver%.*}/${pkgname}-${pkgver}.tar.bz2"
'esound-system.service'
'esound-user.service'
'0001-fix-replace-alsa-drain.patch'
'0002-fix-missing-declaration-for-clean_exit.patch'
'0003-feat-add-nobeeps-to-the-default_options.patch'
'0004-fix-wrong-micro-version.patch'
'0005-revert-close-file-descriptors-after-startup.patch')
b2sums=('39403985557f44b99a6615e42f6772a31b8555cc3bf252140e36f55c812b4728ca7af519267ff1c8f4bd53604d82edbf682d07b16e98158ca39bbe8663bbaadd'
'1b55880c8212f2e85312c632ab79f1ff36d527c7463aa16fb932f324c496a5a67d109372aff657b59812b9fabe8c5978434e078e7a91868298731ab11ea48f2d'
'b84310149765ca3caa7b0b93298af758b0ffbb04b16c3946b3fc8e0ad4e559d7f6221a956dd30a8f01a5e60d85386431078619b683e0d6a447bc1c9363a00e27'
'3c9865c43e8df414e7e7cb6753d88a00dc5859f4ce6272a3e668b442b6d8d4764eaf8c1bef28b5da76ebf26f34b6b30a59fb404f61eb408f0f4889d6c49b8f41'
'8eecd762786fb864e80613d685d66979824600e0b8da0161fdef3a486f592bad1078f7b46afbb45bbd866e50682c6ddcfb0f30cf0d0155516955b4bf3f9b3259'
'b6257eb182838082e366d0dc9836e3fd950f26ecbf9c4dad0c869be492bf3c6c71f661823e586000d42f26381e777cbced96d7c12aca0d9c8f516d3ff77b76bf'
'90c8a34fd771d5cd55f647d87a958aae9b131772086386bfe71b8e9b01142d88cdac276dac52f6863ab778983816c8fe8d26e07e8fd5ba5259e7aa31014a7a32'
'43c4460a11b226d21194acc326cea6c393cd9dd67cd57cc521c7a122d662d79f41d39169dadee4fa057a4e517b3ed69da3ce7e8624c2f8821cb1d8b2de622667')
prepare() {
cd "${srcdir}/${pkgname}-${pkgver}"
patch -i "${srcdir}/0001-fix-replace-alsa-drain.patch"
patch -i "${srcdir}/0002-fix-missing-declaration-for-clean_exit.patch"
patch -i "${srcdir}/0003-feat-add-nobeeps-to-the-default_options.patch"
patch -i "${srcdir}/0004-fix-wrong-micro-version.patch"
patch -i "${srcdir}/0005-revert-close-file-descriptors-after-startup.patch"
}
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
./configure --prefix=/usr \
--sysconfdir=/etc \
--localstatedir=/var \
--enable-alsa \
--enable-ipv6 \
--with-audiofile \
--without-libwrap \
--disable-static \
--disable-artstest
make CFLAGS="${CFLAGS} -lm"
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
make DESTDIR="${pkgdir}" install
# daemon
install -Dm644 "${srcdir}"/esound-system.service "${pkgdir}"/usr/lib/systemd/system/esound.service
install -Dm644 "${srcdir}"/esound-user.service "${pkgdir}"/usr/lib/systemd/user/esound.service
}
|