PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37

# Maintainer: ZephyrDRH <zephyrdrh at gmx dot de>
# Contributor: ziyazzz <dragonleoqinqin@gmail.com>

pkgname=espresso
pkgver=2.4
pkgrel=4
pkgdesc="A tool to produce a minimal equivalent representation of a Boolean function."
arch=("x86_64")
url="https://github.com/chipsalliance/espresso/"
license=("custom")
depends=("glibc")
makedepends=("cmake")
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/chipsalliance/espresso/archive/v${pkgver}.tar.gz")
sha256sums=('27eb2a460877ffb7f92d0dfd44f2abf711e1de1de3de76d214d7bce5de605a1a')

prepare() {
  cd "$srcdir/$pkgname-$pkgver"
  cmake -Bbuild \
    -DCMAKE_INSTALL_BINDIR=/usr/bin \
    -DCMAKE_INSTALL_MANDIR=/usr/share/man \
    -DCMAKE_C_FLAGS="$LDFLAGS $CFLAGS -std=c99"
}

build() {
  cd "$srcdir/$pkgname-$pkgver/build"
  cmake --build . -v
}

check() {
  cd "$srcdir/$pkgname-$pkgver/build"
  ctest
}

package() {
  cd "$srcdir/$pkgname-$pkgver/build"
  DESTDIR="$pkgdir" cmake --install .
}