blob: 4b03853af5e0478daf888604beb07eb0bea31f49 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
|
# Maintainer: Mike Swanson <mikeonthecomputer@gmail.com>
pkgname=eternity-engine-git
pkgver=4.01.00.r65.76d93cb3
pkgrel=1
pkgdesc="An advanced Doom port with vanilla compatibility"
url="http://eternity.youfailit.net/"
arch=('i686' 'x86_64')
license=('GPL3')
depends=('sdl2' 'sdl2_mixer' 'sdl2_net' 'zlib')
makedepends=('git' 'cmake')
conflicts=(${pkgname%-git})
source=(eternity::git+https://github.com/team-eternity/eternity.git
git+https://github.com/Wohlstand/libADLMIDI.git)
b2sums=('SKIP'
'SKIP')
pkgver() {
cd "${srcdir}/eternity"
printf "%s" "$(git describe --long --tags | sed 's/\([^-]*-\)g/r\1/;s/-/./g')"
}
prepare() {
cd "${srcdir}/eternity"
git submodule init
git config submodule.adlmidi.url "${srcdir}/libADLMIDI"
git submodule update
}
build() {
# Cannot do in-tree build.
mkdir ee-build
cd ee-build
cmake ../eternity -DCMAKE_INSTALL_PREFIX=/usr
make
}
package() {
cd ee-build
make PREFIX=/usr DESTDIR="$pkgdir" install
}
|