blob: 0ecbb9b43d9a525e820696f1ca1e103e07f5ac54 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
|
# Maintainer: yjun <jerrysteve1101 at gmail dot com>
# Maintainer: sukanka <su975853527 at gmail dot com>
pkgname=eudic
pkgver=12.5.3
_date=2021-02-06
_lang=en
_flang=English
pkgrel=1
pkgdesc="Proprietary ${_flang} dictionary software for linux"
arch=('x86_64')
url="https://www.eudic.net/v4/${_lang}/app/${pkgname}"
license=('unknown')
depends=(
'hicolor-icon-theme'
'qt5-speech'
'qt5-webkit'
)
source=("${pkgname}-${pkgver}.deb::https://static.frdic.com/pkg/${pkgname}.deb?v=${_date}")
sha256sums=('f1a32e271918b00a80ab3a751ac759ae011569d2875b1b91a495967abc79b801')
# sometime use curl to download source deb, throws 404 not found.
# user other UA instead of origion one fixed it.
# https://wiki.archlinux.org/index.php/Nonfree_applications_package_guidelines#Custom_DLAGENTS
DLAGENTS=("https::/usr/bin/curl -A 'Mozilla' -fLC - --retry 3 --retry-delay 3 -o %o %u")
prepare() {
mkdir -p build
tar -xf data.tar.xz -C build
}
package() {
_dirname=eusoft-${pkgname}
install -dm755 ${pkgdir}/usr/share
cp -pvr build/usr/share/* ${pkgdir}/usr/share/
# link executable
install -dm755 ${pkgdir}/usr/bin/
ln -s /usr/share/${_dirname}/${pkgname} \
${pkgdir}/usr/bin/${pkgname}
# desktop entry
sed -i "s|/usr/share/${_dirname}/AppRun|${pkgname}|g" \
${pkgdir}/usr/share/applications/eusoft-${pkgname}.desktop
# qt plugin path
sed -i '4c Prefix = /usr/lib/qt/' \
${pkgdir}/usr/share/${_dirname}/qt.conf
# remove unused files.
rm -rf ${pkgdir}/usr/share/${_dirname}/{gstreamer-1.0,lib,libcrypto.so.1.0.0,libssl.so.1.0.0,AppRun}
}
# vim: ts=2 sw=2 et:
|