PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43

pkgname=executor-git
pkgver=0.1.0.r437.g27c8ef28
pkgrel=1
pkgdesc="A modern fork of the classic Mac emulator"
arch=('x86_64')
url="https://github.com/autc04/executor"
license=('MIT')
depends=('qt5-base' 'executor-data')
makedepends=('git' 'cmake' 'ruby' 'sdl2' 'libxext' 'python'
             'boost' 'perl')
optdepends=('sdl2: for SDL 2 frontend'
            'libxext: for X11 frontend'
            'waylandpp: for Wayland frontend')
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
source=('git+https://github.com/autc04/executor.git')
sha256sums=('SKIP')
options=(!lto !debug)

pkgver() {
	cd "$srcdir/${pkgname%-git}"
	git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

prepare() {
	cd "$srcdir/${pkgname%-git}"
	git submodule init
	git submodule update
}

build() {
	mkdir "$srcdir/${pkgname%-git}"/build 
	cd "$srcdir/${pkgname%-git}"/build
	cmake ..
	cmake --build . -j 1
}

package() {
	cd "$srcdir/${pkgname%-git}"
	install -Dm755 build/{${pkgname%-git},${pkgname%-git}{-sdl,-sdl2,-wayland,-x}} -t \
		"$pkgdir/usr/bin"
	install -Dm644 COPYING -t "$pkgdir/usr/share/licenses/${pkgname%-git}"
}