blob: 7058124a39cf499a24b23e0f1d3569b49175bf42 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>
pkgname=exfatprogs-git
pkgver=1.1.3.r59.gb8a9b32
pkgrel=1
pkgdesc="exFAT filesystem userspace utilities"
arch=('i686' 'x86_64')
url="https://github.com/exfatprogs/exfatprogs"
license=('GPL')
depends=('glibc')
makedepends=('git')
provides=("exfatprogs=$pkgver" 'exfat-utils')
conflicts=('exfatprogs' 'exfat-utils')
source=("git+https://github.com/exfatprogs/exfatprogs.git#branch=exfat-next")
sha256sums=('SKIP')
pkgver() {
cd "exfatprogs"
_tag=$(git tag -l --sort -v:refname | sed '/rc[0-9]*/d' | head -n1)
_rev=$(git rev-list --count $_tag..HEAD)
_hash=$(git rev-parse --short HEAD)
printf "%s.r%s.g%s" "$_tag" "$_rev" "$_hash" | sed 's/^v//'
}
build() {
cd "exfatprogs"
./autogen.sh
./configure \
--prefix="/usr" \
--sbindir="/usr/bin"
make
}
check() {
cd "exfatprogs"
make check
}
package() {
cd "exfatprogs"
make DESTDIR="$pkgdir" install
}
|