PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49

# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>

pkgname=expat-git
pkgver=2.6.2.r55.g4c3f8641
pkgrel=1
pkgdesc="A stream-oriented XML parser library written in C"
arch=('i686' 'x86_64')
url="https://libexpat.github.io/"
license=('MIT')
depends=('glibc')
makedepends=('git' 'cmake')
provides=("expat=$pkgver" 'libexpat.so')
conflicts=('expat')
source=("git+https://github.com/libexpat/libexpat.git")
sha256sums=('SKIP')


pkgver() {
  cd "libexpat/expat"

  _tag=$(git tag -l --sort -v:refname | grep -E 'R_[0-9_]+$' | head -n1)
  _rev=$(git rev-list --count $_tag..HEAD)
  _hash=$(git rev-parse --short HEAD)
  printf "%s.r%s.g%s" "$_tag" "$_rev" "$_hash" | sed 's/R_//;s/_/./g'
}

build() {
  cd "libexpat/expat"

  cmake \
    -B "_build" \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX="/usr" \
    ./
  make -C "_build"
}

check() {
  cd "libexpat/expat"

  #make -C "_build" test
}

package() {
  cd "libexpat/expat"

  make -C "_build" DESTDIR="$pkgdir" install
  install -Dm644 "COPYING" -t "$pkgdir/usr/share/licenses/expat"
}