blob: 868f48a6889aa97b40d5d57c9519eaa122d3821b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
|
# Maintainer: Kyle Manna <kyle(at)kylemanna(dot)com>
# Co-Maintainer: WorMzy Tykashi <wormzy.tykashi@gmail.com>
pkgname=expressvpn
pkgver=1.3.0
pkgrel=1
pkgdesc="Proprietary VPN client for Linux"
arch=('x86_64' 'i686')
url="https://expressvpn.com"
license=('custom')
# net-tools is needed for old skool ifconfig
depends=('net-tools')
_date=$(date +%Y%m%d)
options=(!strip)
install=expressvpn.install
source=("license-${_date}.html::https://www.expressvpn.com/vpn-software/vpn-linux/open-source")
_url="https://download.expressvpn.xyz/clients/linux"
source_x86_64=("${_url}/${pkgname}_${pkgver}_amd64.deb"{,.asc})
source_i686=("${_url}/${pkgname}_${pkgver}_i386.deb"{,.asc})
sha512sums=('SKIP')
sha512sums_x86_64=('8bccd03e837dde245671391c2bb9e3f692c206c3d372e3ad22a65633d6c282636e008830dba215a8cb0c1d07f13321c24dadfcfef25d42cc78427e8afb29c1d4'
'SKIP')
sha512sums_i686=('946a85c7ae5f31a38b3b6c91f6890188a72472f867d71ef69bf8f4f038d02f2ab9a7f137ea5eacad1e87b7de46ae3cd1227345710b2dd9c152221dfc036b2cbb'
'SKIP')
validpgpkeys=('1D0B09AD6C93FEE93FDDBD9DAFF2A1415F6A3A38')
package() {
# /usr/sbin is a symlink to /usr/bin, rewrite it
bsdtar -C "${pkgdir}" -xf "${srcdir}/data.tar.gz" -s ":/usr/sbin:/usr/bin:"
# Install service file to correct place
install -Dm644 "${pkgdir}/usr/lib/expressvpn/expressvpn.service" "${pkgdir}/usr/lib/systemd/system/expressvpn.service"
# Fix service file
sed -i -e 's:RestartSe=:RestartSec=:' -e '/EnvironmentFile/d' "${pkgdir}/usr/lib/systemd/system/expressvpn.service"
# Install bash-completion to correct place
install -Dm644 "${pkgdir}/usr/lib/expressvpn/bash-completion" "${pkgdir}/usr/share/bash-completion/completions/expressvpn"
install -Dm644 "${srcdir}/license-${_date}.html" "${pkgdir}/usr/share/licenses/${pkgname}/license.html"
install -dm755 "$pkgdir/var/lib/expressvpn/certs"
# Remove unused /etc
rm -r "$pkgdir/etc/"
# Remove sysv script
rm "$pkgdir/usr/lib/expressvpn/expressvpn.init"
}
|