blob: 4024981e45b22ed6b75c065e7f3e389cce3064ce (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
|
# Maintainer: Kyle Manna <kyle(at)kylemanna(dot)com>
# Co-Maintainer: WorMzy Tykashi <wormzy.tykashi@gmail.com>
pkgname=expressvpn
pkgver=3.21.0.2_1
pkgrel=1
pkgdesc="Proprietary VPN client for Linux"
arch=('x86_64' 'i686' 'armv7h')
url="https://expressvpn.com"
license=('custom')
options=(!strip)
install=expressvpn.install
_url="https://www.expressvpn.works/clients/linux"
source_x86_64=("${_url}/${pkgname}_${pkgver/_/-}_amd64.deb"{,.asc})
source_i686=("${_url}/${pkgname}_${pkgver/_/-}_i386.deb"{,.asc})
source_armv7h=("${_url}/${pkgname}_${pkgver/_/-}_armhf.deb"{,.asc})
sha512sums_x86_64=('1ed3a091c55bfa7f5dc06bd306239b51506859d8a01f0f2d7a81571320c3b9c5c36aead47f86e1eb1039c5ade37fcbc8d7b3b50eb7e8ecc407bff4ce0ab1e369'
'SKIP')
sha512sums_i686=('0b110b29bfc9dbb3a3040f6c6311aa8cc4bfcf1835507737d52cd1623c5912112edec1012b90365abe4b994fea7502284b9605a21e409a261e551590a80fe14f'
'SKIP')
sha512sums_armv7h=('a9b5a5328b1d5a8f4ba5f780bcf6176fdc35b8d39540038a53e216d41fafad7c5d01b76c36b7f7fe7f139f8f85981bb98180ffdce1f3e10aa499c13c897673b7'
'SKIP')
validpgpkeys=('1D0B09AD6C93FEE93FDDBD9DAFF2A1415F6A3A38')
package() {
# /usr/sbin is a symlink to /usr/bin, rewrite it. Upstream also install files to both /lib and /usr/lib
# merge these and move to correct location
bsdtar -C "${pkgdir}" -xf "${srcdir}/data.tar.gz" -s ":/usr/sbin:/usr/bin:" -s ":/usr/lib:/lib:"
mv "${pkgdir}/lib" "${pkgdir}/usr/"
install -dm755 "${pkgdir}/usr/share/licenses/${pkgname}"
ln -s "/usr/share/doc/expressvpn/COPYRIGHT" "${pkgdir}/usr/share/licenses/${pkgname}/COPYRIGHT"
install -dm755 "${pkgdir}/var/lib/expressvpn/certs"
# Remove unused /etc
rm -r "$pkgdir/etc/"
}
|