blob: 0b1a7bf76484fd6c32bcf03ad0e2b52a7685c482 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
|
# Maintainer: Kyle Manna <kyle(at)kylemanna(dot)com>
# Co-Maintainer: WorMzy Tykashi <wormzy.tykashi@gmail.com>
pkgname=expressvpn
pkgver=3.52.0.2_1
pkgrel=1
pkgdesc="Proprietary VPN client for Linux"
arch=('x86_64' 'i686' 'armv7h')
url="https://expressvpn.com"
license=('custom')
options=(!strip)
install=expressvpn.install
_url="https://www.expressvpn.works/clients/linux"
source_x86_64=("${_url}/${pkgname}_${pkgver/_/-}_amd64.deb"{,.asc})
source_i686=("${_url}/${pkgname}_${pkgver/_/-}_i386.deb"{,.asc})
source_armv7h=("${_url}/${pkgname}_${pkgver/_/-}_armhf.deb"{,.asc})
sha512sums_x86_64=('346c618271c3574300ce78ea754ce5aa131c24e1c43f183b433a27f2753a348fc2ff9e5d54d50a10aa2056dbf170a17eaa2664c83668914b8879e252591458eb'
'SKIP')
sha512sums_i686=('7af9e689d6851df76403208ae933c137b9295974ff9d3d434072e07b25dd7f4c6d75ce4e01542bad355c7bfaf2a90899dbd2babdbb094783bed13ad70e64b6f1'
'SKIP')
sha512sums_armv7h=('1711ee21b2076e0e91089f6343e3c85a046a57968fb1c752d31d94783faef1665b42b84efc430c6b90e734d4f452324e832497a255c1e66f56490a141ec6f424'
'SKIP')
validpgpkeys=('1D0B09AD6C93FEE93FDDBD9DAFF2A1415F6A3A38')
package() {
# /usr/sbin is a symlink to /usr/bin, rewrite it. Upstream also install files to both /lib and /usr/lib
# merge these and move to correct location
bsdtar -C "${pkgdir}" -xf "${srcdir}/data.tar.gz" -s ":/usr/sbin:/usr/bin:" -s ":/usr/lib:/lib:"
mv "${pkgdir}/lib" "${pkgdir}/usr/"
install -dm755 "${pkgdir}/usr/share/licenses/${pkgname}"
ln -s "/usr/share/doc/expressvpn/COPYRIGHT" "${pkgdir}/usr/share/licenses/${pkgname}/COPYRIGHT"
install -dm755 "${pkgdir}/var/lib/expressvpn/certs"
# Remove unused /etc
rm -r "$pkgdir/etc/"
}
|