blob: 2353efdbaf30c1bc66ebc940d440cbb1a0940746 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
|
# Maintainer: Kyle Manna <kyle(at)kylemanna(dot)com>
# Co-Maintainer: WorMzy Tykashi <wormzy.tykashi@gmail.com>
pkgname=expressvpn
pkgver=2.5.1.1_1
pkgrel=1
pkgdesc="Proprietary VPN client for Linux"
arch=('x86_64' 'i686' 'armv7h')
url="https://expressvpn.com"
license=('custom')
# net-tools is needed for old skool ifconfig
depends=('net-tools')
_date=$(date +%Y%m%d)
options=(!strip)
install=expressvpn.install
source=("license-${_date}.html::https://www.expressvpn.com/vpn-software/vpn-linux/open-source")
_url="https://download.expressvpn.xyz/clients/linux"
source_x86_64=("${_url}/${pkgname}_${pkgver/_/-}_amd64.deb"{,.asc})
source_i686=("${_url}/${pkgname}_${pkgver/_/-}_i386.deb"{,.asc})
source_armv7h=("${_url}/${pkgname}_${pkgver/_/-}_armhf.deb"{,.asc})
sha512sums=('SKIP')
sha512sums_x86_64=('003033ae36368f05791820f8b198653e78c869ff99eac87a9e2da088193ab0ea3a743464717b34fa96ac1c87046baa8a37fb10dbaee9d4fd463f26dbabf8c9df'
'SKIP')
sha512sums_i686=('be632cf36b566ec571d458002c856760ae8533175ac99694d48473a1274c3cc7d845a06032d4abf28575f6e5125602cc831ea10e9f18871a30aaeb8da53df2f4'
'SKIP')
sha512sums_armv7h=('6779952793ad225a158942ea8847373c0d3f8898132fe49e0da31bff3880f57a57e558ad08850d9608981542a95628d6bca974da406cfdc18ce17cb771459e4a'
'SKIP')
validpgpkeys=('1D0B09AD6C93FEE93FDDBD9DAFF2A1415F6A3A38')
package() {
# /usr/sbin is a symlink to /usr/bin, rewrite it
bsdtar -C "${pkgdir}" -xf "${srcdir}/data.tar.gz" -s ":/usr/sbin:/usr/bin:"
# Install service file to correct place
install -Dm644 "${pkgdir}/usr/lib/expressvpn/expressvpn.service" "${pkgdir}/usr/lib/systemd/system/expressvpn.service"
# Install bash-completion to correct place
install -Dm644 "${pkgdir}/usr/lib/expressvpn/bash-completion" "${pkgdir}/usr/share/bash-completion/completions/expressvpn"
install -Dm644 "${srcdir}/license-${_date}.html" "${pkgdir}/usr/share/licenses/${pkgname}/license.html"
install -dm755 "$pkgdir/var/lib/expressvpn/certs"
# Remove unused /etc
rm -r "$pkgdir/etc/"
# Remove sysv script
rm "$pkgdir/usr/lib/expressvpn/expressvpn.init"
}
|