blob: 5ea58846ca7f51fca5ae194b77d76072a3ee8007 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
|
# Maintainer: Kyle Manna <kyle(at)kylemanna(dot)com>
# Co-Maintainer: WorMzy Tykashi <wormzy.tykashi@gmail.com>
pkgname=expressvpn
pkgver=3.63.0.4_1
pkgrel=1
pkgdesc="Proprietary VPN client for Linux"
arch=('x86_64' 'i686' 'armv7h')
url="https://expressvpn.com"
license=('custom')
options=(!strip)
install=expressvpn.install
_url="https://www.expressvpn.works/clients/linux"
source_x86_64=("${_url}/${pkgname}_${pkgver/_/-}_amd64.deb"{,.asc})
source_i686=("${_url}/${pkgname}_${pkgver/_/-}_i386.deb"{,.asc})
source_armv7h=("${_url}/${pkgname}_${pkgver/_/-}_armhf.deb"{,.asc})
sha512sums_x86_64=('869b99a955904fcfd394e8591f835749825b945085b6bdf5d4b0c90a61855d24528d23a66952c45a5addf799bd196c9b7851a6ac6bbe889da6c5169ced54aea6'
'SKIP')
sha512sums_i686=('20a414cb95a2a592f6ae59396caa915f78d20d0b9bf6fc93fd528b37faaf06059204ccdadc7f4bc779ef3114e1d0c5cbc73819fe696456da046aedf5c949ff5c'
'SKIP')
sha512sums_armv7h=('0c73aad145fbee2cfc5a1bd0dd1fd8c6fb50372276eea698f1d3fcde2d43bbc62c205595ae1fbd94b5394ae5652dc9b94e621ee12be326e435be153d942ad041'
'SKIP')
validpgpkeys=('1D0B09AD6C93FEE93FDDBD9DAFF2A1415F6A3A38')
package() {
# /usr/sbin is a symlink to /usr/bin, rewrite it. Upstream also install files to both /lib and /usr/lib
# merge these and move to correct location
bsdtar -C "${pkgdir}" -xf "${srcdir}/data.tar.gz" -s ":/usr/sbin:/usr/bin:" -s ":/usr/lib:/lib:"
mv "${pkgdir}/lib" "${pkgdir}/usr/"
install -dm755 "${pkgdir}/usr/share/licenses/${pkgname}"
ln -s "/usr/share/doc/expressvpn/COPYRIGHT" "${pkgdir}/usr/share/licenses/${pkgname}/COPYRIGHT"
install -dm755 "${pkgdir}/var/lib/expressvpn/certs"
# Remove unused /etc
rm -r "$pkgdir/etc/"
}
|