blob: 8ce549ac424cb4f51eeb53e4825c3ce68242b070 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
# Maintainer: Kyle Manna <kyle(at)kylemanna(dot)com>
# Co-Maintainer: WorMzy Tykashi <wormzy.tykashi@gmail.com>
pkgname=expressvpn
pkgver=2.3.3_1
pkgrel=1
pkgdesc="Proprietary VPN client for Linux"
arch=('x86_64' 'i686' 'armv7h')
url="https://expressvpn.com"
license=('custom')
# net-tools is needed for old skool ifconfig
depends=('net-tools')
_date=$(date +%Y%m%d)
options=(!strip)
install=expressvpn.install
source=("license-${_date}.html::https://www.expressvpn.com/vpn-software/vpn-linux/open-source")
_url="https://download.expressvpn.xyz/clients/linux"
source_x86_64=("${_url}/${pkgname}_${pkgver/_/-}_amd64.deb"{,.asc})
source_i686=("${_url}/${pkgname}_${pkgver/_/-}_i386.deb"{,.asc})
source_armv7h=("${_url}/${pkgname}_${pkgver/_/-}_armhf.deb"{,.asc})
sha512sums=('SKIP')
sha512sums_x86_64=('a3f75324e1b47beaf357b077b05f66c6d2ee3a8811d22f8618ddd486bc89b6f51be47c083abcdbd91ab5574e5d11b6588db3b66431ba5f22be0da36546185984'
'SKIP')
sha512sums_i686=('16fcd623d414c68e7878b6e7f173182eef135ef6c1e06d1e89891aae6b64ff04ae75c67b6bb6fbcca00a24b33089d42dc864adc1854eaf8814f07730f71d3518'
'SKIP')
sha512sums_armv7h=('ec32236bb8fdda0f4fb93ca85c80e3dca2bc5f5df28c6320724d024e75524d4cda70a83e21ff9890bd60452a05d35e4ae23d0fe3ea0c960122a67f78d55d820a'
'SKIP')
validpgpkeys=('1D0B09AD6C93FEE93FDDBD9DAFF2A1415F6A3A38')
package() {
# /usr/sbin is a symlink to /usr/bin, rewrite it
bsdtar -C "${pkgdir}" -xf "${srcdir}/data.tar.gz" -s ":/usr/sbin:/usr/bin:"
# Install service file to correct place
install -Dm644 "${pkgdir}/usr/lib/expressvpn/expressvpn.service" "${pkgdir}/usr/lib/systemd/system/expressvpn.service"
# Install bash-completion to correct place
install -Dm644 "${pkgdir}/usr/lib/expressvpn/bash-completion" "${pkgdir}/usr/share/bash-completion/completions/expressvpn"
install -Dm644 "${srcdir}/license-${_date}.html" "${pkgdir}/usr/share/licenses/${pkgname}/license.html"
install -dm755 "$pkgdir/var/lib/expressvpn/certs"
# Remove unused /etc
rm -r "$pkgdir/etc/"
# Remove sysv script
rm "$pkgdir/usr/lib/expressvpn/expressvpn.init"
}
|