blob: d4776b909e62286fa9a710fcc5bf3e538e438b6d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
|
# Maintainer: Kyle Manna <kyle(at)kylemanna(dot)com>
# Co-Maintainer: WorMzy Tykashi <wormzy.tykashi@gmail.com>
pkgname=expressvpn
pkgver=3.58.0.2_1
pkgrel=1
pkgdesc="Proprietary VPN client for Linux"
arch=('x86_64' 'i686' 'armv7h')
url="https://expressvpn.com"
license=('custom')
options=(!strip)
install=expressvpn.install
_url="https://www.expressvpn.works/clients/linux"
source_x86_64=("${_url}/${pkgname}_${pkgver/_/-}_amd64.deb"{,.asc})
source_i686=("${_url}/${pkgname}_${pkgver/_/-}_i386.deb"{,.asc})
source_armv7h=("${_url}/${pkgname}_${pkgver/_/-}_armhf.deb"{,.asc})
sha512sums_x86_64=('381c61ad8358a74e245e3ab6dd7351bd83ac34a439c6a4670c01e3289e3cb7d921b693378cb19e62e6c6b9723472ad2e2b131f4731b1c005828ff4d1e4dd26e0'
'SKIP')
sha512sums_i686=('7e028870d98f3bf1142901144ae4ca03f4b92de3c437d18cff51f658449325f3801339c9aabb850058a271a4a0710963dd434cdb3fb681e7cf7fd619de0d0191'
'SKIP')
sha512sums_armv7h=('8ca58b8cdcb6e6575ea3e821e9a97d39df63e090652658587f7404c2e29fb7dfb11875c63e02d727ec66783dd50365a0f51c98b45b4d8d1dc1d90e39e825132e'
'SKIP')
validpgpkeys=('1D0B09AD6C93FEE93FDDBD9DAFF2A1415F6A3A38')
package() {
# /usr/sbin is a symlink to /usr/bin, rewrite it. Upstream also install files to both /lib and /usr/lib
# merge these and move to correct location
bsdtar -C "${pkgdir}" -xf "${srcdir}/data.tar.gz" -s ":/usr/sbin:/usr/bin:" -s ":/usr/lib:/lib:"
mv "${pkgdir}/lib" "${pkgdir}/usr/"
install -dm755 "${pkgdir}/usr/share/licenses/${pkgname}"
ln -s "/usr/share/doc/expressvpn/COPYRIGHT" "${pkgdir}/usr/share/licenses/${pkgname}/COPYRIGHT"
install -dm755 "${pkgdir}/var/lib/expressvpn/certs"
# Remove unused /etc
rm -r "$pkgdir/etc/"
}
|