blob: 7d81499a725ee107d1df6f20e271cf88c6ab3c0f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
|
# Maintainer: Kyle Manna <kyle(at)kylemanna(dot)com>
# Co-Maintainer: WorMzy Tykashi <wormzy.tykashi@gmail.com>
pkgname=expressvpn
pkgver=3.8.0.4_1
pkgrel=1
pkgdesc="Proprietary VPN client for Linux"
arch=('x86_64' 'i686' 'armv7h')
url="https://expressvpn.com"
license=('custom')
# net-tools is needed for old skool ifconfig
depends=('net-tools')
_date=$(date +%Y%m%d)
options=(!strip)
install=expressvpn.install
source=("license-${_date}.html::https://www.expressvpn.com/vpn-software/vpn-linux/open-source")
_url="https://download.expressvpn.xyz/clients/linux"
source_x86_64=("${_url}/${pkgname}_${pkgver/_/-}_amd64.deb"{,.asc})
source_i686=("${_url}/${pkgname}_${pkgver/_/-}_i386.deb"{,.asc})
source_armv7h=("${_url}/${pkgname}_${pkgver/_/-}_armhf.deb"{,.asc})
sha512sums=('SKIP')
sha512sums_x86_64=('ae0fd4575d2aa55d089caabe27cd1f03ff8cd9ed27ee56766c7b3e13b5b3c8d194d31f916765eaa9d428e21fc096f0f83a03d3c1e2559eb196a3405ddcd8f31a'
'SKIP')
sha512sums_i686=('9600f7501f2cece68f3ecbc41f29ec825cd18715224cd1280b7d30622628189275fc2c684bfc8184a3ef61dce55187a8c6aeef894e059ab42365042e4eabe0e8'
'SKIP')
sha512sums_armv7h=('9faa49bde9764a1cd61918502ee37fa0b6833b2b02825cb8a75e8680e8cb93c3da1d60913e7b010b80a5dac92157ae567b7a40239df738a77ae079311ba442c9'
'SKIP')
validpgpkeys=('1D0B09AD6C93FEE93FDDBD9DAFF2A1415F6A3A38')
package() {
# /usr/sbin is a symlink to /usr/bin, rewrite it
bsdtar -C "${pkgdir}" -xf "${srcdir}/data.tar.gz" -s ":/usr/sbin:/usr/bin:"
# Install service file to correct place
install -Dm644 "${pkgdir}/usr/lib/expressvpn/expressvpn.service" "${pkgdir}/usr/lib/systemd/system/expressvpn.service"
# Install bash-completion to correct place
install -Dm644 "${pkgdir}/usr/lib/expressvpn/bash-completion" "${pkgdir}/usr/share/bash-completion/completions/expressvpn"
install -Dm644 "${srcdir}/license-${_date}.html" "${pkgdir}/usr/share/licenses/${pkgname}/license.html"
install -dm755 "$pkgdir/var/lib/expressvpn/certs"
# Remove unused /etc
rm -r "$pkgdir/etc/"
# Remove sysv script
rm "$pkgdir/usr/lib/expressvpn/expressvpn.init"
}
|