blob: 4613039e87dd35fa74536c94b5dce1781036f7fe (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
# Maintainer: Kyle Manna <kyle(at)kylemanna(dot)com>
# Co-Maintainer: WorMzy Tykashi <wormzy.tykashi@gmail.com>
pkgname=expressvpn
pkgver=2.3.4_1
pkgrel=1
pkgdesc="Proprietary VPN client for Linux"
arch=('x86_64' 'i686' 'armv7h')
url="https://expressvpn.com"
license=('custom')
# net-tools is needed for old skool ifconfig
depends=('net-tools')
_date=$(date +%Y%m%d)
options=(!strip)
install=expressvpn.install
source=("license-${_date}.html::https://www.expressvpn.com/vpn-software/vpn-linux/open-source")
_url="https://download.expressvpn.xyz/clients/linux"
source_x86_64=("${_url}/${pkgname}_${pkgver/_/-}_amd64.deb"{,.asc})
source_i686=("${_url}/${pkgname}_${pkgver/_/-}_i386.deb"{,.asc})
source_armv7h=("${_url}/${pkgname}_${pkgver/_/-}_armhf.deb"{,.asc})
sha512sums=('SKIP')
sha512sums_x86_64=('70408e25ef3b14d83aa25f0d3a3abd57c5470e61e7cc24a1362311406c5735b6bf4c959fdbbe7a39db6bf72b269820dd1797c31db01bae9c9f86ff0c24a3795c'
'SKIP')
sha512sums_i686=('34d72be4722df419b86a13ae0b35478d4f6759ca58f0d2827b48f9233dab3dfe25f2b3e5ab0df606257fba9ff1bf41c37e9a6b88691d7fa680bf8c8eb267bd5a'
'SKIP')
sha512sums_armv7h=('10749720e162769d5b91f76f11b49bceb815d3571b5c284720ec621d8d0351071ac60f7bcbc6518b4d1626eef240a3e6f0a6ae1be9083ccd16be21cbc6edb9da'
'SKIP')
validpgpkeys=('1D0B09AD6C93FEE93FDDBD9DAFF2A1415F6A3A38')
package() {
# /usr/sbin is a symlink to /usr/bin, rewrite it
bsdtar -C "${pkgdir}" -xf "${srcdir}/data.tar.gz" -s ":/usr/sbin:/usr/bin:"
# Install service file to correct place
install -Dm644 "${pkgdir}/usr/lib/expressvpn/expressvpn.service" "${pkgdir}/usr/lib/systemd/system/expressvpn.service"
# Install bash-completion to correct place
install -Dm644 "${pkgdir}/usr/lib/expressvpn/bash-completion" "${pkgdir}/usr/share/bash-completion/completions/expressvpn"
install -Dm644 "${srcdir}/license-${_date}.html" "${pkgdir}/usr/share/licenses/${pkgname}/license.html"
install -dm755 "$pkgdir/var/lib/expressvpn/certs"
# Remove unused /etc
rm -r "$pkgdir/etc/"
# Remove sysv script
rm "$pkgdir/usr/lib/expressvpn/expressvpn.init"
}
|