blob: 925bb0a337514eaa48deff770d426883d6aa07d1 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
|
# Maintainer: steffeno <steffeno dash etc at protonmail dot com>
_pkgname=ext4magic
pkgname=$_pkgname-patch-extent-free
pkgver=0.3.2
pkgrel=4
pkgdesc="Upstream $_pkgname-$pkgver package, patched not to segfault"
arch=('x86_64')
url='https://sourceforge.net/projects/ext4magic/'
license=('GPL2')
depends=('bzip2' 'file' 'util-linux' 'e2fsprogs')
conflicts=($_pkgname)
source=("$url/files/$_pkgname-$pkgver.tar.gz"
"$url/files/Patches/workaround.patch"
'01-i_dir_acl.patch'
'02-Fix-undefined-reference-to-makedev.patch'
'03-Fix-segfault-extent-free.patch')
sha256sums=('8d9c6a594f212aecf4eb5410d277caeaea3adc03d35378257dfd017ef20ea115'
'89468a7857778bd171490cddfc1f4ce8b8308c46353e8c01998dc054373f5fff'
'2b5cde2612370f49fa9ed8442c23425499bdcf67aaba442087eb11f1c8b51e06'
'850378bcee22c9e4888c7ebb77085db29747383e5a272795be18341d4426f2db'
'b8f4660c11c7e91edd85caa848a009b1a11b168cb80dec9cf7f23ac9d90dcdab')
prepare() {
cd $_pkgname-$pkgver
# apply patch from the source array (should be a pacman feature)
local filename
for filename in "${source[@]}"; do
if [[ "$filename" =~ \.patch$ ]]; then
echo "Applying patch ${filename##*/}"
patch -p1 -N -i "$srcdir/${filename##*/}"
fi
done
:
}
build() {
cd $_pkgname-$pkgver
./configure --prefix=/usr --sbindir=/usr/bin
make
}
package() {
cd $_pkgname-$pkgver
make DESTDIR="$pkgdir" install
}
# vim:set ts=2 sw=2 et:
|