blob: 5878be12eef2245194871a81c9715c87fbdedf64 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
|
# Maintainer: Sebastien Duthil <duthils@free.fr>
# Inspiration for service and config files: https://github.com/Bisa/factorio-init
pkgname=factorio-headless
pkgver=0.12.26
pkgrel=4
pkgdesc="A 2D game about building and maintaining factories - Server version"
arch=('x86_64')
url="http://www.factorio.com/"
license=('custom: commercial')
conflicts=('factorio' 'factorio-demo' 'factorio-experimental')
install=factorio-headless.install
source=(LICENSE
factorio-headless.service
factorio-headless.conf
factorio-headless.sysusers
factorio_headless_x64_${pkgver}.tar.gz::http://www.factorio.com/get-download/${pkgver}/headless/linux64)
sha256sums=('67ec2f88afff5d7e0ca5fd3301b5d98655269c161a394368fa0ec49fbc0c0e21'
'7ba176d90c55c86312f59aa664cbe33e72dea2fc88a746f0c3029cee84837ab6'
'082f6da53d1a90c2aa040e35d8912b02084c7d2011c9f8d784487723e05597dc'
'87dae15d1bcfb4683faea9c66498bd916bd27f8aa0dc724c4e21076dcf17da64'
'a7891432c675cc9ac3577c627e348d5f0aca9c06478a659a4e703f5813c79dad')
# no modifications needed, the executable looks for:
# - data in /usr/share/factorio
# - config in ~/.factorio
package() {
install -Dm755 "${srcdir}/factorio/bin/x64/factorio" "$pkgdir/usr/bin/factorio"
install -d "${pkgdir}/usr/share/factorio"
cp -r "${srcdir}/factorio/data"/* "${pkgdir}/usr/share/factorio"
install -Dm644 "${srcdir}/LICENSE" "${pkgdir}/usr/share/licenses/factorio-headless/LICENSE"
install -Dm644 "${srcdir}/factorio-headless.sysusers" "$pkgdir/usr/lib/sysusers.d/factorio.conf"
install -Dm644 "${srcdir}/factorio-headless.conf" "${pkgdir}/etc/conf.d/factorio"
install -Dm644 "${srcdir}/factorio-headless.service" "${pkgdir}/usr/lib/systemd/system/factorio.service"
}
|