blob: 8418099c5a9a53c88c0773164f42828235929724 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
# Maintainer: Younes Khoudli <khoyobegenn@gmail.com>
# Contributor: Eli Schwartz <eschwartz@archlinux.org>
_pkgname=FanFicFare
pkgname=fanficfare
pkgver=4.16.0
pkgrel=1
pkgdesc="A tool for downloading fanfiction to eBook formats"
arch=('any')
url="https://github.com/JimmXinu/${_pkgname}"
license=('Apache')
changelog=changelog.txt
_deps=('beautifulsoup4' 'brotli' 'chardet' 'cloudscraper' 'html5lib' 'html2text'
'requests-file')
depends=("${_deps[@]/#/python-}")
optdepends=('calibre: use FanFicFare as a calibre plugin'
'python-pillow: support for converting/resizing story images and covers')
source=("${pkgname}-${pkgver}.tar.gz::${url}/archive/v${pkgver}.tar.gz"
"0001-makeplugin-do-not-bundle-system-dependencies.patch")
sha256sums=('b88e3e04f36be92ea71b82141dc4ac196e4651433400537f18f1d4c95e2e2fad'
'6d172dcc98a8f6dcef2048272bfabd810ceeb5740969fbe406ebcd7b638e072c')
b2sums=('f0b7b59f2667bfb3b8f3e9fe7f570307e1969fe2e1e4311a300b808acc6df868263fd626c0765e8519a01c4e40e77db291a50a4353ed3291a9101480e31d94d5'
'eca0e505305ef74e0af1be6f5c1376091da4cd69bfc9f468f6040cf35d71890e3901b9cf0a9f9e25e6cb409651d402d8414116d0a8d43269bfdab2fdd0005279')
prepare() {
cd "${srcdir}/${_pkgname}-${pkgver}"
patch -p1 -i ../0001-makeplugin-do-not-bundle-system-dependencies.patch
}
build() {
cd "${srcdir}/${_pkgname}-${pkgver}"
python setup.py build
for i in calibre-plugin/translations/*.po; do
msgfmt -vv "$i" -o "${i%.po}.mo"
done
python makeplugin.py
}
package() {
cd "${srcdir}/${_pkgname}-${pkgver}"
python setup.py install --root="${pkgdir}" --optimize=1 --skip-build
install -Dm644 FanFicFare.zip "${pkgdir}"/usr/share/calibre/system-plugins/FanFicFare.zip
}
|