blob: 79e56471b8a3994173f26742675903affbd16ab2 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
|
# Maintainer: Cristo Cola <cristomcflirt@gmail.com>
pkgname=fast-folder
pkgver=1.0.0
pkgrel=1
pkgdesc="Template-driven project folder generator with TUI and browser UI (fastf)"
arch=(x86_64)
url="https://github.com/cristocola/fast-folder"
license=(MIT)
depends=(gcc-libs)
makedepends=(cargo)
optdepends=('chromium: dedicated app window for fastf ui --app')
source=("$pkgname-$pkgver.tar.gz::$url/archive/refs/tags/v$pkgver.tar.gz")
sha256sums=('19b5e8f4dbc82ede06bb288c975bde5f5c79c6c0a472408c60bbc656f4961457')
prepare() {
cd "$pkgname-$pkgver"
export RUSTUP_TOOLCHAIN=stable
cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
}
build() {
cd "$pkgname-$pkgver"
export RUSTUP_TOOLCHAIN=stable
export CARGO_TARGET_DIR=target
cargo build --frozen --release
}
check() {
cd "$pkgname-$pkgver"
export RUSTUP_TOOLCHAIN=stable
# Tests are hermetic: they redirect all state via FASTF_INSTALL_DIR.
cargo test --frozen --release
}
package() {
cd "$pkgname-$pkgver"
local bin=target/release/fastf
install -Dm755 "$bin" "$pkgdir/usr/bin/fastf"
install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
# Shell completions (generated by the built binary; writes nothing to $HOME)
"$bin" completions bash | install -Dm644 /dev/stdin "$pkgdir/usr/share/bash-completion/completions/fastf"
"$bin" completions zsh | install -Dm644 /dev/stdin "$pkgdir/usr/share/zsh/site-functions/_fastf"
"$bin" completions fish | install -Dm644 /dev/stdin "$pkgdir/usr/share/fish/vendor_completions.d/fastf.fish"
# Man pages
"$bin" mangen man
install -Dm644 man/*.1 -t "$pkgdir/usr/share/man/man1/"
# Desktop integration (browser UI launcher)
install -Dm644 packaging/fastf.desktop "$pkgdir/usr/share/applications/fastf.desktop"
for size in 48 128 256; do
install -Dm644 "packaging/icons/fastf-$size.png" \
"$pkgdir/usr/share/icons/hicolor/${size}x${size}/apps/fastf.png"
done
}
|