blob: 864f439f8eed018604042ce33c8da05fc2532a9e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
|
# Maintainer: vitaliikuzhdin <vitaliikuzhdin@gmail.com>
pkgname="fast-ssh"
pkgver=0.3.2
pkgrel=2
pkgdesc="Quickly connect to your services by navigating through your SSH config"
arch=(
'x86_64'
)
url="https://github.com/Julien-R44/${pkgname}"
license=(
'MIT'
)
depends=(
'glibc'
'libgcc'
'openssh'
)
makedepends=(
'cargo'
)
_pkgsrc="${url##*/}-${pkgver}"
source=(
"${url}/archive/refs/tags/v${pkgver}/${_pkgsrc}.tar.gz"
)
sha256sums=('36f9bbd91297766cd72d40a1db6484e334022d674bb81c8dfa73c4cc2f0b6844')
_source() {
export CARGO_HOME="${srcdir}/.cargo"
export CARGO_TARGET_DIR=target
export RUSTUP_TOOLCHAIN=stable
}
prepare() {
_source
cd "${srcdir}/${_pkgsrc}"
cargo fetch --locked --target host-tuple
}
build() {
_source
cd "${srcdir}/${_pkgsrc}"
cargo build --frozen --release --all-features
}
check() {
_source
cd "${srcdir}/${_pkgsrc}"
cargo test --frozen --all-features
}
package() {
cd "${srcdir}/${_pkgsrc}"
install -vDm755 "target/release/${pkgname}" "${pkgdir}/usr/bin/${pkgname}"
install -vDm644 "README.md" "${pkgdir}/usr/share/doc/${pkgname}/README.md"
install -vDm644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
|