blob: 9a7e7cb1be165bc4d0092e8e57b5e55641787155 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
|
# Maintainer: Mark Wagie <mark dot wagie at proton dot me>
pkgname=fastfetch
pkgver=2.1.2
pkgrel=2
pkgdesc="Like Neofetch, but much faster because written in C"
arch=('x86_64' 'aarch64' 'riscv64')
url="https://github.com/fastfetch-cli/fastfetch"
license=('MIT')
depends=('gcc-libs')
makedepends=(
'chafa'
'cmake'
'dbus'
'dconf'
'ddcutil'
'directx-headers'
'imagemagick'
'libnm'
'libpulse'
'libxcb'
'libxrandr'
'mesa'
'ocl-icd'
'opencl-headers'
'pciutils'
'vulkan-headers'
'vulkan-icd-loader'
'wayland'
'xfconf'
'zlib'
)
optdepends=(
'chafa: Image output as ascii art'
'dbus: Bluetooth, Player & Media detection'
'dconf: Needed for values that are only stored in DConf + Fallback for GSettings'
'ddcutil: Brightness detection of external displays'
'directx-headers: GPU detection in WSL'
'glib2: Output for values that are only stored in GSettings'
'imagemagick: Image output using sixel or kitty graphics protocol'
'libnm: Wifi detection'
'libpulse: Sound detection'
'mesa: Needed by the OpenGL module for gl context creation.'
'libxrandr: Multi monitor support'
'ocl-icd: OpenCL module'
'pciutils: GPU output'
'vulkan-icd-loader: Vulkan module & fallback for GPU output'
'xfconf: Needed for XFWM theme and XFCE Terminal font'
'zlib: Faster image output when using kitty graphics protocol'
)
source=("$pkgname-$pkgver.tar.gz::$url/archive/refs/tags/$pkgver.tar.gz")
sha256sums=('62b02c7e48cb328c4381e7d4af4b23a7c74a2879eeea53525b8c45cc0e79e65f')
build() {
cmake -B build -S "$pkgname-$pkgver" \
-DCMAKE_BUILD_TYPE='RelWithDebInfo' \
-DCMAKE_INSTALL_PREFIX='/usr' \
-DBUILD_TESTS='ON' \
-DENABLE_SQLITE3='OFF' \
-DENABLE_RPM='OFF' \
-DENABLE_IMAGEMAGICK6='OFF' \
-DENABLE_DDCUTIL='ON' \
-Wno-dev
cmake --build build
}
check() {
ctest --test-dir build --output-on-failure
}
package() {
DESTDIR="$pkgdir" cmake --install build
}
|