blob: d5eff6f75be65ec71314fb3e86b54162e3f2a4e1 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
|
# Maintainer: Mark Wagie <mark dot wagie at tutanota dot com>
pkgname=fastfetch
pkgver=1.9.0
pkgrel=1
pkgdesc="Like Neofetch, but much faster because written in C"
arch=('x86_64')
url="https://github.com/LinusDierheimer/fastfetch"
license=('MIT')
depends=('gcc-libs')
makedepends=('chafa' 'cmake' 'dbus' 'dconf' 'imagemagick' 'libnm' 'libxcb'
'libxrandr' 'mesa' 'ocl-icd' 'opencl-headers' 'pciutils'
'vulkan-headers' 'vulkan-icd-loader' 'wayland' 'xfconf' 'zlib')
optdepends=(
'chafa: Image output as ascii art'
'dbus: Needed for detecting current media player and song'
'dconf: Needed for values that are only stored in DConf + Fallback for GSettings'
'glib2: Output for values that are only stored in GSettings'
'imagemagick: Image output using sixel or kitty graphics protocol'
'libnm: Used for Wifi detection'
'mesa: Needed by the OpenGL module for gl context creation.'
'libxrandr: Multi monitor support'
'ocl-icd: OpenCL module'
'pciutils: GPU output'
'vulkan-icd-loader: Vulkan module & fallback for GPU output'
'xfconf: Needed for XFWM theme and XFCE Terminal font'
'zlib: Faster image output when using kitty graphics protocol'
)
backup=("etc/$pkgname/config.conf")
source=("$pkgname-$pkgver.tar.gz::$url/archive/refs/tags/$pkgver.tar.gz")
sha256sums=('b43b8f3053a417b8138918d2efb46172ddc8d42183ad8707fb1dace63917e448')
build() {
cmake -B build -S "$pkgname-$pkgver" \
-DCMAKE_BUILD_TYPE='RelWithDebInfo' \
-DCMAKE_INSTALL_PREFIX='/usr' \
-DBUILD_TESTS='ON' \
-DENABLE_SQLITE3='OFF' \
-DENABLE_RPM='OFF' \
-DENABLE_IMAGEMAGICK6='OFF' \
-DENABLE_LIBCJSON='OFF' \
-Wno-dev
cmake --build build
}
check() {
ctest --test-dir build --output-on-failure
}
package() {
DESTDIR="$pkgdir" cmake --install build
}
|