PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38

# Maintainer: AlphaJack <alphajack at tuta dot io>

pkgname="fava-dashboards-git"
pkgver=r93.50a0b7c
pkgrel=1
pkgdesc="Custom Dashboards for Beancount in Fava"
url="https://github.com/andreasgerstmayr/fava-dashboards"
license=("GPL3")
arch=("any")
depends=(    "fava"
             "beanquery"
             "python-pyaml")
makedepends=("git"
             "python-build"
             "python-installer"
             "python-hatchling"
             "python-hatch-vcs"
             "python-setuptools-scm"
             "python-wheel")
options=("!strip")
#source=("git+$url#branch=update-project-layout")
source=("git+$url")
sha256sums=("SKIP")

pkgver() {
 cd "fava-dashboards"
 printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short=7 HEAD)"
}

build(){
 cd "fava-dashboards"
 python -m build --wheel --no-isolation
}

package(){
 cd "fava-dashboards"
 python -m installer --destdir="$pkgdir" dist/*.whl
}