PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40

# Maintainer: AlphaJack <alphajack at tuta dot io>

pkgname="fava-portfolio-returns-git"
pkgver=r42.de68b54
pkgrel=1
pkgdesc="Show portfolio returns in Fava"
url="https://github.com/andreasgerstmayr/fava-portfolio-returns"
license=("GPL3")
arch=("any")
depends=(    "fava"
             "beangrow"
             "python-scipy"
             "python-matplotlib")
makedepends=("npm"
             "esbuild"
             "git"
             "python-build"
             "python-installer"
             "python-setuptools-scm"
             "python-wheel")
options=("!strip")
source=("git+$url")
b2sums=("SKIP")

pkgver() {
 cd "fava-portfolio-returns"
 printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short=7 HEAD)"
}

build(){
 cd "fava-portfolio-returns"
 python -m build --wheel --no-isolation
 npm install echarts
 make build
}

package(){
 cd "fava-portfolio-returns"
 python -m installer --destdir="$pkgdir" dist/*.whl
}