blob: 324ea103eff12ec340ebbe6ab237fcc5e5d36390 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
|
# Maintainer: Luis Martinez <luis dot martinez at disroot dot org>
# Contributor: Kaare Jenssen <kaare at jenssen dot it>
# Contributor: Dan Beste <dan.ray.beste@gmail.com>
pkgname=fd-git
pkgver=8.2.0.r114.gf1b39d4
pkgrel=1
pkgdesc='A simple, fast and user-friendly alternative to find.'
arch=('i686' 'x86_64')
url='https://github.com/sharkdp/fd'
license=('APACHE' 'MIT')
depends=('gcc-libs')
makedepends=('git' 'cargo')
provides=("fd=$pkgver")
conflicts=('fd')
source=("$pkgname::git+$url")
sha256sums=('SKIP')
pkgver() {
git -C "$pkgname" describe --long --tags | sed 's/v//g;s/\([^-]*-g\)/r\1/;s/-/./g'
}
prepare() {
cd "$pkgname"
cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
}
build() {
export RUSTUP_TOOLCHAIN=stable
export CARGO_TARGET_DIR=target
cd "$pkgname"
cargo build --release --frozen --all-features
}
check() {
export RUSTUP_TOOLCHAIN=stable
cd "$pkgname"
cargo test --frozen --all-features
}
package() {
cd "$pkgname"
install -D target/release/fd -t "$pkgdir/usr/bin/"
install -Dm644 target/release/build/fd-find-*/out/fd.bash "$pkgdir/usr/share/bash-completion/completions/fd"
install -Dm644 target/release/build/fd-find-*/out/fd.fish -t "$pkgdir/usr/share/fish/vendor_completions.d/"
install -Dm644 contrib/completion/_fd -t "$pkgdir/usr/share/zsh/site-functions/"
install -Dm644 doc/fd.1 -t "$pkgdir/usr/share/man/man1/"
install -Dm644 LICENSE-{APACHE,MIT} -t "$pkgdir/usr/share/licenses/$pkgname/"
}
# vim:set ts=2 sw=2 et:
|