blob: 2a23359bb74aee36b9675787cc4049d7108f472c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
|
# Maintainer: Dan Beste <dan.ray.beste@gmail.com>
pkgname='fd-rs-git'
pkgver=5.0.0.r3.gc022528
pkgrel=1
pkgdesc='A simple, fast and user-friendly alternative to find.'
arch=('i686' 'x86_64')
url='https://github.com/sharkdp/fd'
license=('APACHE' 'MIT')
makedepends=('git' 'rust')
provides=("${pkgname/-git}")
conflicts=("${pkgname/-git}")
source=("${pkgname}::git+https://github.com/sharkdp/fd.git")
sha256sums=('SKIP')
pkgver() {
cd "${pkgname}"
git describe --long --tags \
| sed 's/v//g;s/\([^-]*-g\)/r\1/;s/-/./g'
}
build() {
cd "${pkgname}"
cargo build --release
}
check() {
cd "${pkgname}"
cargo test
}
package() {
cd "${pkgname}"
install -d "${pkgdir}/usr/bin"
install -d "${pkgdir}/usr/share/licenses/${pkgname}"
install -m 755 \
"target/release/${pkgname/-rs-git}" \
"${pkgdir}/usr/bin/${pkgname/-rs-git}"
install -m 644 \
LICENSE-APACHE \
"${pkgdir}/usr/share/licenses/${pkgname}/LICENSE-APACHE"
install -m 644 \
LICENSE-MIT \
"${pkgdir}/usr/share/licenses/${pkgname}/LICENSE-MIT"
}
# vim: ts=2 sw=2 et:
|