blob: 41afb08a1602ba33c60159eaa0994d0ea662796c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
|
# Maintainer: Helle Vaanzinn <glitsj16 at riseup dot net >
pkgname=fdns
pkgver=0.9.64.2
pkgrel=2
pkgdesc="Firejail DNS-over-HTTPS proxy server"
arch=(x86_64)
license=(GPL2)
url="https://github.com/netblue30/fdns"
depends=('libseccomp' 'openssl')
optdepends=('apparmor: support for apparmor profiles'
'bash-completion: bash completion'
'firejail: seamless integration support'
'systemd: run fdns as a systemd service')
validpgpkeys=('F951164995F5C4006A73411E2CCB36ADFC5849A7')
source=("https://github.com/netblue30/fdns/releases/download/v${pkgver}/${pkgname}-${pkgver}.tar.xz"{,.asc}
"resolver.seccomp.patch::https://github.com/netblue30/fdns/commit/76fc538ce6e7e29307429c77bcce6a0e69c8f6fa")
sha256sums=('1ecfb371748df2654f1ce9d14dde3f2f9266a50a9dbcff51122fb941ccc07236'
'SKIP'
'0979216a81f4f9b824bf7bcafbd541f14ec064703eb38126fd1e100dc8dbe574')
prepare() {
cd "${srcdir}/${pkgname}-${pkgver}"
patch -Np1 < ../resolver.seccomp.patch # Update for kernel 5.11
}
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
./configure --prefix=/usr
make
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
make DESTDIR="$pkgdir" install
# license
install -Dm644 "${pkgdir}/usr/share/doc/${pkgname}/COPYING" \
"${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
rm -f "${pkgdir}/usr/share/doc/${pkgname}/COPYING"
}
|