blob: 8a1eb3b0a23e0993e6d41401feb2722235f3956e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
|
# Maintainer: Helle Vaanzinn <glitsj16 at riseup dot net>
_pkgname=fdns
pkgname=${_pkgname}-git
pkgver=0.9.69+g4164b1f
pkgrel=1
pkgdesc="Firejail DNS-over-HTTPS proxy server - git version"
arch=(x86_64)
url="https://github.com/netblue30/fdns"
license=(GPL2)
backup=(
etc/fdns/adblocker
etc/fdns/coinblocker
etc/fdns/fp-trackers
etc/fdns/phishing
etc/fdns/resolver.seccomp
etc/fdns/servers
etc/fdns/trackers
)
depends=(
libseccomp
openssl
)
makedepends=(
git
)
optdepends=('apparmor: support for apparmor profiles'
'bash-completion: bash completion'
'firejail: seamless integration support'
'systemd: run fdns as a systemd service')
provides=("$_pkgname")
conflicts=("$_pkgname")
source=("git+https://github.com/netblue30/fdns.git"
"fdns.hardened.service::https://github.com/netblue30/fdns/raw/39711eac58e60ae2d02052223aabbf22b5379906/etc/fdns.service")
sha256sums=('SKIP'
'e7f1f0d58b3333c5fa10740886967a6acc674c28d2bcfe77356254c1dd6ffc62')
pkgver() {
cd "$_pkgname"
#git describe --tags | sed -e 's/-/+/g' -e 's/^v//'
_version="$(grep "PACKAGE_VERSION=" configure | awk '{split($0,a,"="); print a[2]}' | sed "s/'//g")"
_tag="$(git describe --tags | sed -e 's/-/+/g' -e 's/^v//' | awk '{split($0,a,"+"); print a[3]}')"
echo "${_version}+${_tag}"
}
build() {
cd "$_pkgname"
./configure --prefix=/usr --enable-apparmor --with-systemd=/usr/lib/systemd/system
make
}
package() {
cd "$_pkgname"
make DESTDIR="$pkgdir" install
# use hardened systemd service
rm -f "${pkgdir}/usr/lib/systemd/system/${_pkgname}.service"
install -D -m 0644 "${srcdir}/${_pkgname}.hardened.service" \
"${pkgdir}/usr/lib/systemd/system/${_pkgname}.service"
# license
install -D -m 0644 "${pkgdir}/usr/share/doc/${_pkgname}/COPYING" \
"${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
rm -f "${pkgdir}/usr/share/doc/${_pkgname}/COPYING"
}
|