blob: b8fe8314691bad124d5014ede588e7b66101e149 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
# Maintainer: Brian Bidulock <bidulock@openss7.org>
pkgname=fence-agents
pkgver=4.11.0
pkgrel=1
pkgdesc="OCF fence agents for rgmanager and pacemaker"
arch=('i686' 'x86_64')
url='http://clusterlabs.org/'
license=('GPL2')
makedepends=('libxslt' 'python' 'docbook-xsl')
depends=('python-pexpect' 'openwsman' 'python-pycurl' 'python-requests' 'python-boto3' 'python-suds')
source=("$pkgname-$pkgver.tar.gz::https://github.com/ClusterLabs/$pkgname/archive/v$pkgver.tar.gz")
sha512sums=('21be9fcbc6f49815ca989d4f7b584cb1793b360be34da3b0afa9c0e21dbf2c7db363716abd702ba38f7863904c7a3bd26caba2005b0572d6e336c052f210328f')
prepare() {
cd $pkgname-$pkgver
echo "$pkgver" >.tarball-version
./autogen.sh
}
build() {
cd $pkgname-$pkgver
./configure --prefix=/usr \
--bindir=/usr/bin \
--sbindir=/usr/bin \
--libdir=/usr/lib \
--libexecdir=/usr/lib \
--sysconfdir=/etc \
--localstatedir=/var \
--with-systemdsystemunitdir=/usr/lib/systemd/system \
--with-agents="alom amt amt_ws apc apc_snmp aws azure_arm bladecenter brocade cisco_mds cisco_ucs compute docker drac dummy eaton_snmp emerson eps evacuate hds_cb heuristics_ping hpblade ibmblade ifmib ilo ilo_moonshot ilo_mp ilo_ssh intelmodular ipdu ipmilan ironic kdump ldom lpar manual mpath netio ovh powerman pve raritan rcd_serial rhevm rsa rsb sanbox2 sbd scsi vbox virsh vmware vmware_rest vmware_soap vmware_vcloud wti xenapi zvm"
make V=0
}
package() {
cd $pkgname-$pkgver
make DESTDIR="${pkgdir}" install
rm -fr "${pkgdir}/var"
rm -fr "${pkgdir}/etc/init.d"
install -Dm644 /dev/null "${pkgdir}/usr/lib/tmpfiles.d/fence-agents.conf"
( echo "# /usr/lib/tmpfiles.d/fence-agents.conf"
echo "d /run/fence-agents 0755 root root -"
)>>"${pkgdir}/usr/lib/tmpfiles.d/fence-agents.conf"
}
# vim: set sw=2 et:
|