blob: e049573b8978b926f84b9fefde4fbd8a16207e1b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
|
# Maintainer: KokaKiwi <kokakiwi+aur at kokakiwi dot net>
_pkgver=5.6.0-nightly.53
pkgname=ferdi-nightly-bin
pkgver=${_pkgver/-/.}
pkgrel=1
pkgdesc='A messaging browser that allows you to combine your favorite messaging services into one application - nightly binary version'
url='https://getferdi.com'
license=('Apache')
arch=('x86_64')
depends=('alsa-lib' 'c-ares' 'ffmpeg' 'gtk3' 'http-parser'
'libevent' 'libnghttp2' 'libsecret' 'libxkbfile'
'libxslt' 'libxss' 'libxtst'
'minizip' 'nss' 're2' 'snappy')
provides=('ferdi')
conflicts=('ferdi' 'ferdi-bin')
source=("${pkgname}-${_pkgver}.rpm::https://github.com/getferdi/nightlies/releases/download/v${_pkgver}/ferdi-${_pkgver}.x86_64.rpm")
sha256sums=('61c7e7033a1abf3524b7731f98d29f9f043d84a0dc48197f3352e0ba53b2d1bd')
b2sums=('b40d31dc14b0470e3132b79b92feb658a3dcad214a0bd945b32964c5ccbda6de1d4f40d32f83437d4833c9730b5e1466cd2956f327c85d3759bb6ba911f5d68a')
prepare() {
sed -E -i -e 's|Exec=/opt/Ferdi/ferdi|Exec=/usr/bin/ferdi|' usr/share/applications/ferdi.desktop
}
package() {
install -dm0755 "${pkgdir}"/{opt,usr}
cp -a --no-preserve=ownership opt/Ferdi "${pkgdir}/opt/ferdi"
cp -a --no-preserve=ownership usr/share "${pkgdir}/usr/share"
install -dm0755 "${pkgdir}/usr/bin"
ln -sf /opt/ferdi/ferdi "${pkgdir}/usr/bin/ferdi"
install -dm0755 "${pkgdir}/usr/share/licenses/${pkgname}"
ln -sf -t "${pkgdir}/usr/share/licenses/${pkgname}" \
/opt/ferdi/{LICENSE.electron.txt,LICENSES.chromium.html}
}
|