blob: 3b2d77df5fbd3b86c6c02a37de48344595b0f19c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
|
# Maintainer: Thibaud Kehler <thibaud.kehler at gmx dot net>
pkgname='fet-timetabling'
_module='fet'
pkgver=7.12.1
pkgrel=1
pkgdesc="A software for automatically scheduling the timetable of a school, high-school or university."
arch=('x86_64')
url="https://lalescu.ro/liviu/fet/"
license=('AGPL3')
depends=('qt6-base' 'hicolor-icon-theme')
makedepends=('cmake')
source=("https://lalescu.ro/liviu/fet/download/fet-${pkgver}.tar.xz")
sha256sums=('6a4305d5dda5efecde920fafc7c6b51d80ce47966b9e8e60bb76078da0bd4246')
build() {
cd "$srcdir/$_module-$pkgver"
# Use qt-cmake as recommended by the author
mkdir -p build
cd build
/usr/lib/qt6/bin/qt-cmake .. \
-DCMAKE_BUILD_TYPE=Release \
-DCMAKE_INSTALL_PREFIX=/usr \
-DUSE_SYSTEM_LOCALE=ON \
-DCMAKE_INSTALL_DATADIR=/usr/share
cmake --build .
}
package() {
cd "$srcdir/$_module-$pkgver/build"
find .qt/ -name "deploy_fet_*.cmake" -exec truncate -s 0 {} + 2>/dev/null || true
DESTDIR="${pkgdir}" cmake --install . --prefix /usr
}
|