blob: a70c1362308ebc9431ebfd9795e1f21ac10daa87 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
|
# Maintainer: Ben Widawsky <ben@bwidawsk.net>
# Contributor: Rob McCathie <korrode at gmail>
# Contributor: Ionut Biru <ibiru@archlinux.org>
# Contributor: Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
# Contributor: Maxime Gauduin <alucryd@archlinux.org>
# Contributor: Tom Newsom <Jeepster@gmx.co.uk>
# Contributor: Paul Mattal <paul@archlinux.org>
_name=ffmpeg
pkgname=ffmpeg-libfdk_aac
pkgver=2.8.1
pkgrel=1
epoch=1
pkgdesc='Complete solution to record, convert and stream audio and video (Same as official package except with libfdk-aac support)'
arch=('i686' 'x86_64')
url='http://ffmpeg.org/'
license=('GPL3' 'custom:libfdk-aac')
depends=(
'alsa-lib' 'bzip2' 'fontconfig' 'fribidi' 'gnutls' 'gsm' 'lame' 'libass'
'libbluray' 'libmodplug' 'libpulse' 'libsoxr' 'libssh' 'libtheora'
'libva' 'libvdpau' 'libwebp' 'opencore-amr' 'openjpeg' 'opus'
'schroedinger' 'sdl' 'speex' 'v4l-utils' 'xvidcore' 'zlib'
'libvorbis.so' 'libvorbisenc.so' 'libvpx.so' 'libx264.so' 'libx265.so'
'libfdk-aac'
)
makedepends=('hardening-wrapper' 'ladspa' 'libvdpau' 'yasm')
optdepends=('ladspa: LADSPA filters')
provides=(
"ffmpeg=$pkgver"
'libavcodec.so' 'libavdevice.so' 'libavfilter.so' 'libavformat.so'
'libavresample.so' 'libavutil.so' 'libpostproc.so' 'libswresample.so'
'libswscale.so'
)
conflicts=("$_name")
source=(http://ffmpeg.org/releases/$_name-$pkgver.tar.bz2{,.asc}
ffmpeg-2.8.1-libvpxenc-remove-some-unused-ctrl-id-mappings.patch)
validpgpkeys=('FCF986EA15E6E293A5644F10B4322F04D67658D8') # ffmpeg-devel
md5sums=('63b2cfeea930e942ff7579fd0064c5be'
'SKIP'
'71be9bcd297cb9ce833bbc5d425c0470')
prepare() {
cd $_name-$pkgver
patch -p1 -i ../ffmpeg-2.8.1-libvpxenc-remove-some-unused-ctrl-id-mappings.patch
}
build() {
cd $_name-$pkgver
./configure \
--prefix=/usr \
--disable-debug \
--disable-static \
--disable-stripping \
--enable-avisynth \
--enable-avresample \
--enable-fontconfig \
--enable-gnutls \
--enable-gpl \
--enable-ladspa \
--enable-libass \
--enable-libbluray \
--enable-libfreetype \
--enable-libfribidi \
--enable-libgsm \
--enable-libmodplug \
--enable-libmp3lame \
--enable-libopencore_amrnb \
--enable-libopencore_amrwb \
--enable-libopenjpeg \
--enable-libopus \
--enable-libpulse \
--enable-libschroedinger \
--enable-libsoxr \
--enable-libspeex \
--enable-libssh \
--enable-libtheora \
--enable-libv4l2 \
--enable-libvidstab \
--enable-libvorbis \
--enable-libvpx \
--enable-libwebp \
--enable-libx264 \
--enable-libx265 \
--enable-libxvid \
--enable-shared \
--enable-version3 \
--enable-x11grab \
--enable-libfdk_aac \
--enable-nonfree
make
make tools/qt-faststart
make doc/ff{mpeg,play,server}.1
cp /usr/share/licenses/libfdk-aac/NOTICE .
}
package() {
cd $_name-$pkgver
make DESTDIR="$pkgdir" install install-man
install -Dm755 tools/qt-faststart "$pkgdir"/usr/bin/qt-faststart
install -d "$pkgdir/usr/share/licenses/$pkgname"
install -m 0644 NOTICE "$pkgdir/usr/share/licenses/$pkgname/NOTICE"
}
|