blob: 5ba05c5a708211cab4b1227b4e2c896b4d80887f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
|
# Maintainer: willemw <willemw12@gmail.com>
pkgname=ffmpeg-normalize-git
pkgver=1.33.1.r0.gdd689b5
pkgrel=4
pkgdesc='Normalize loudness of audio and video files using FFmpeg'
arch=(any)
url=https://github.com/slhck/ffmpeg-normalize
license=(MIT)
depends=(ffmpeg python-colorlog python-ffmpeg-progress-yield python-mutagen python-tqdm)
checkdepends=(git python-pytest uv)
makedepends=(git python-installer python-uv-build uv)
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
source=("$pkgname::git+$url.git")
sha512sums=('SKIP')
pkgver() {
git -C $pkgname describe --long | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
prepare() {
git -C $pkgname clean -dfx
}
build() {
cd $pkgname
#python -m build --no-isolation --wheel
uv --no-cache --no-managed-python --offline build --no-build-isolation --out-dir=dist --wheel .
}
check() {
cd $pkgname
uv venv --no-managed-python --system-site-packages
uv --no-cache --no-managed-python --offline pip install --link-mode=copy --no-deps dist/*.whl
PATH=".venv/bin:$PATH" ./.venv/bin/python -m pytest tests
}
package() {
cd $pkgname
install -Dm644 LICENSE.md -t "$pkgdir/usr/share/licenses/${pkgname%-git}"
python -m installer --destdir="$pkgdir" dist/*.whl
}
|