blob: 7c007246bdd615521555688bbd63ee807dbfebaa (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
|
# Maintainer: Francois Menning <f.menning@pm.me>
# Contributor: Maxime Gauduin <alucryd@archlinux.org>
# Contributor: Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
# Contributor: Ionut Biru <ibiru@archlinux.org>
# Contributor: Tom Newsom <Jeepster@gmx.co.uk>
# Contributor: Paul Mattal <paul@archlinux.org>
# Contributor: Daniel Bermond < yahoo-com: danielbermond >
# Contributor: Iacopo Isimbaldi <isiachi@rhye.it>
# Contributor: Ben Widawsky <ben@bwidawsk.net>
_srcname=ffmpeg
pkgname=ffmpeg-qsv
pkgver=4.0.3
pkgrel=1
pkgdesc='Complete solution to record, convert and stream audio and video (including qsv and libfdk-aac)'
arch=('x86_64')
url='http://www.ffmpeg.org/'
license=('GPL3' 'custom: nonfree and unredistributable')
depends=(
'alsa-lib' 'aom' 'bzip2' 'fontconfig' 'fribidi' 'glibc' 'gmp' 'gnutls' 'gsm'
'jack' 'lame' 'libavc1394' 'libdrm' 'libiec61883' 'libmodplug'
'libomxil-bellagio' 'libpulse' 'libraw1394' 'libsoxr' 'libssh' 'libtheora'
'libvdpau' 'libwebp' 'libx11' 'libxcb' 'libxext' 'libxml2' 'libxv'
'opencore-amr' 'openjpeg2' 'opus' 'sdl2' 'speex' 'v4l-utils' 'xz' 'zlib'
'libass.so' 'libbluray.so' 'libfreetype.so' 'libva-drm.so' 'libva.so'
'libva-x11.so' 'libvidstab.so' 'libvorbisenc.so' 'libvorbis.so' 'libvpx.so'
'libx264.so' 'libx265.so' 'libxvidcore.so' 'libfdk-aac' 'intel-media-sdk'
)
makedepends=('ffnvcodec-headers' 'git' 'ladspa' 'yasm' 'opencl-headers')
optdepends=(
'ladspa: LADSPA filters'
'compute-runtime: Intel(R) Graphics Compute Runtime for OpenCL(TM).'
'beignet: OpenCL implementation for Intel IvyBridge+ iGPUs'
'opencl-mesa: OpenCL support for AMD/ATI Radeon mesa drivers'
'opencl-amd: OpenCL userspace driver as provided in the amdgpu-pro driver stack'
'opencl-nvidia: OpenCL implemention for NVIDIA'
)
provides=(
'ffmpeg' 'ffmpeg-libfdk_aac' 'qt-faststart'
'libavcodec.so' 'libavdevice.so' 'libavfilter.so' 'libavformat.so'
'libavutil.so' 'libpostproc.so' 'libswresample.so' 'libswscale.so'
)
conflicts=(
'ffmpeg' 'ffmpeg-full-nvenc' 'ffmpeg-nvenc' 'ffmpeg-libfdk_aac' 'ffmpeg-decklink'
'ffmpeg-git' 'ffmpeg-full-git' 'ffmpeg-semifull-git' 'ffmpeg-qsv-git')
source=("git+https://git.ffmpeg.org/ffmpeg.git#tag=n${pkgver}" 'LICENSE')
sha256sums=('SKIP'
'04a7176400907fd7db0d69116b99de49e582a6e176b3bfb36a03e50a4cb26a36')
build() {
cd ffmpeg
export PKG_CONFIG_PATH="${PKG_CONFIG_PATH:+${PKG_CONFIG_PATH}:}/opt/intel/mediasdk/lib64/pkgconfig"
./configure \
--prefix='/usr' \
--extra-libs='-lpthread' \
--disable-debug \
--disable-static \
--disable-stripping \
--enable-fontconfig \
--enable-gmp \
--enable-gnutls \
--enable-gpl \
--enable-ladspa \
--enable-libaom \
--enable-libass \
--enable-libbluray \
--enable-libdrm \
--enable-libfreetype \
--enable-libfribidi \
--enable-libgsm \
--enable-libiec61883 \
--enable-libjack \
--enable-libmodplug \
--enable-libmp3lame \
--enable-libopencore_amrnb \
--enable-libopencore_amrwb \
--enable-libopenjpeg \
--enable-libopus \
--enable-libpulse \
--enable-libsoxr \
--enable-libspeex \
--enable-libssh \
--enable-libtheora \
--enable-libv4l2 \
--enable-libvidstab \
--enable-libvorbis \
--enable-libvpx \
--enable-libwebp \
--enable-libx264 \
--enable-libx265 \
--enable-libxcb \
--enable-libxml2 \
--enable-libxvid \
--enable-nvdec \
--enable-nvenc \
--enable-omx \
--enable-shared \
--enable-version3 \
--enable-nonfree \
--enable-iconv \
--enable-opencl \
--enable-opengl \
--enable-libfdk_aac \
--enable-libmfx \
--enable-vaapi \
--enable-vdpau
make
make tools/qt-faststart
make doc/ff{mpeg,play}.1
}
package() {
make DESTDIR="${pkgdir}" -C ffmpeg install install-man
install -Dm 755 ffmpeg/tools/qt-faststart "${pkgdir}"/usr/bin/
install -Dm 644 "${srcdir}/LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
|